F.A.Q. SergeiStrelec
Как можно сделать экспорт/импорт WLAN-профилей, чтобы не вводить данные каждый раз вручную?
Все сохраненные WLAN профили на компьютере хранятся в папке "ProgramData\Microsoft\Wlansvc\Profiles\Interfaces"
Ключ находится там как параметр keyMaterial в зашифрованном виде, выглядит как длинный набор букв и цифр.
Команда экспорта профиля выглядит так: netsh wlan export profile key=clear (key=clear расшифровывает ключ при экспорте)
Это стандартная команда от Microsoft для сохранения профилей, а затем их применения при переустановке ОС например,
чтоб не вводить все заново.
Поэтому "батник" должен выполнятся от имени Администратора, иначе ключ просто не расшифруется и работать не будет.
То есть в образ он должен быть помещен в расшифрованном виде, то есть его реальное значение,
иначе он правильно работать не будет. При импорте профиля он опять шифруется системой.
Автоматизация экспорта и импорта профилей:
1. Включить показ расширений для зарегистрированных типов файлов.
2. Создать папку с именем WLAN и в ней создать два текстовых файла: export.bat и import.bat
3. Открыть в блокноте файл export.bat, скопировать код для export.bat и вставить его в открытый export.bat. Сохранить изменения в файле.
4. Открыть в блокноте файл import.bat, скопировать код для import.bat и вставить его в открытый import.bat. Сохранить изменения в файле.
5. Перенести папку WLAN на PC, с которого нужно экспортировать профили, перейти в нее и запустить с правами Администратора файл export.bat.
6. В появившемся каталоге WLAN\_WLANProfiles должны будут появится XML-файлы с профилями, определите нужный вам профиль(или профили) и удалите не нужные.
7. Перенести папку WLAN на PC, на который нужно экспортировать профили, перейти в нее и запустить с правами Администратора файл import.bat
8. Если папка WLAN\_WLANProfiles более не нужна, то ее можно удалить.
Содержимое export.bat:
@echo off
set wpdir=%~dp0_WLANProfiles
if not exist "%wpdir%" mkdir "%wpdir%"
netsh wlan export profile key=clear folder="%wpdir%"
cd /d "%wpdir%"
for /f "delims=" %%i in ('dir /a:-d /b') do (
for /f "delims=- tokens=2" %%j in ('echo %%i') do (
move /y "%%i" "%%j"
)
)
pause
exit
Содержимое import.bat:
@echo off
set wpdir=%~dp0_WLANProfiles
cd /d "%wpdir%"
for /f "delims=" %%i in ('dir /a:-d /b') do (
netsh wlan add profile filename="%%i" user=all
)
pause
exit
Вход
Регистрация
![[Цитировать]](./styles/templates/default/images/lang/ru/icon_quote.gif "Ответить с цитатой"){kind=icon}
Отправлено: 
Это совершенно разные вещи.
-Вадя, ты не прааав... 
