ChkDskGui (PureBasic)

Import "user32.lib"
  OemToCharBuffA(*Buff,*Buff1,SizeBuff)
EndImport
Procedure.s ReadProgramStringOem(iPid)
  Protected Ret$=""
  Protected SizeBuff=AvailableProgramOutput(iPid)
  If SizeBuff>0
    Protected *Buff=AllocateMemory(SizeBuff)
    ReadProgramData(iPid,*Buff,SizeBuff)
    OemToCharBuffA(*Buff,*Buff,SizeBuff)
    Ret$=PeekS(*Buff,SizeBuff,#PB_Ascii)
    FreeMemory(*Buff)
  EndIf
  ProcedureReturn Ret$
EndProcedure
Procedure.s Cn(Str$)
  Protected i,j=1,Ret$="",Sym$,Str1$="",Flag=0
  Str$=ReplaceString(Str$,Chr(13)+Chr(10),Chr(12))
  For i=1 To Len(Str$)
    Sym$=Mid(Str$,i,1)
    Select Sym$
      Case Chr(12)
        Ret$+Str1$+Chr(13)+Chr(10)
        Str1$=""
      Case Chr(13)
        Flag=1
      Default
        If Flag:Str1$="":Flag=0:EndIf
        Str1$+Sym$
    EndSelect
  Next
  Ret$+Str1$
  ProcedureReturn Ret$
EndProcedure
Procedure EditorEndLine(Gadget)
Protected sel.CHARRANGE, GadgetID, LineEnd
GadgetID=GadgetID(Gadget)
LineEnd = SendMessage_(GadgetID, #EM_GETLINECOUNT, 0, 0)-1
sel\cpMin=SendMessage_(GadgetID, #EM_LINEINDEX, LineEnd, 0)
sel\cpMax=sel\cpMin
SendMessage_(GadgetID, #EM_EXSETSEL, 0, @sel)
EndProcedure
Procedure Chkdsk()
  ;    Protected iPid = RunProgram("cmd.exe", "/c tracert usbtor.ru", "", #PB_Program_Open | #PB_Program_Read | #PB_Program_Hide)
  ;    Protected iPid = RunProgram("cmd.exe", "/c chkdsk d: /f /x", "", #PB_Program_Open | #PB_Program_Read | #PB_Program_Hide)
  Protected iPid = RunProgram("cmd.exe", "/c chkdsk c: ", "", #PB_Program_Open | #PB_Program_Read | #PB_Program_Hide)
  Protected Str$,Text$=""
  If iPid
    While ProgramRunning(iPid)
      If WaitWindowEvent(100) = #PB_Event_CloseWindow
        If MessageRequester("Внимание!", "Идет сканирование диска..."+Chr(10)+"Закрыть программу?", #PB_MessageRequester_YesNo | #MB_ICONQUESTION)=6
          CloseProgram(iPid)
          End
        EndIf
      EndIf
      Str$=ReadProgramStringOem(iPid)
      If Str$
        Text$+Str$
        SetGadgetText(0,Cn(Text$)+Chr(13)+Chr(10))
        EditorEndLine(0)
      EndIf
    Wend
    CloseProgram(iPid) ; Close the connection to the program
  EndIf
EndProcedure
Procedure SizeWindowHandler()
  ResizeGadget(0,0,0,WindowWidth(0),WindowHeight(0))
EndProcedure
OpenWindow(0,  44, 16, 700, 300, "CHKDSK GUI", #PB_Window_SystemMenu | #PB_Window_MinimizeGadget | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget)
SendMessage_(WindowID(0),#WM_SETICON,0,ExtractIcon_(0,"Shell32.dll",270))
BindEvent(#PB_Event_SizeWindow, @SizeWindowHandler())
SmartWindowRefresh(0, #True)
WindowBounds(0, 500, 200, #PB_Ignore, #PB_Ignore)
EditorGadget(0, 0, 0, 700, 300, #PB_Editor_ReadOnly)
SendMessage_(GadgetID(0),#EM_SETTARGETDEVICE, #Null, 0)
LoadFont(0, "Courier New", 10)
SetGadgetFont(0, FontID(0))
Chkdsk()
Repeat
Until WaitWindowEvent() = #PB_Event_CloseWindow

Procedure SizeWindowHandler()
  ResizeGadget(0,0,0,WindowWidth(0),WindowHeight(0))
EndProcedure
OpenWindow(0,  44, 16, 700, 300, "CHKDSK GUI", #PB_Window_SystemMenu | #PB_Window_MinimizeGadget | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget)
SendMessage_(WindowID(0),#WM_SETICON,0,ExtractIcon_(0,"Shell32.dll",270))
BindEvent(#PB_Event_SizeWindow, @SizeWindowHandler())
SmartWindowRefresh(0, #True)
WindowBounds(0, 500, 200, #PB_Ignore, #PB_Ignore)
EditorGadget(0, 0, 0, 700, 300, #PB_Editor_ReadOnly)
SendMessage_(GadgetID(0),#EM_SETTARGETDEVICE, #Null, 0)
Courier_New=LoadFont(0, "Courier New", 10)
SetGadgetFont(0, Courier_New)
Text$="Тип файловой системы: NTFS." +Chr(13)+Chr(10)
Text$ +"Тип файловой системы: NTFS." +Chr(13)+Chr(10)
Text$ + "Тип файловой системы: NTFS." +Chr(13)+Chr(10)
Text$ + "Тип файловой системы: NTFS."
SetGadgetFont(0, LoadFont(0, "Courier New", 10))
Repeat
  SetGadgetText(0,Text$+Chr(13)+Chr(10))
Until WaitWindowEvent(1) = #PB_Event_CloseWindow