Изменение имени компьютера на этапе разворачивания системы из "заливки" образа *.wim

@echo off
set sys=Windows\System32\config\SYSTEM
set /p var="New PC NAME?:"
echo/
set _drvs=& for %%i in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do ^
if exist %%i:\%sys% if %%i: neq %SystemDrive% call set _drvs=%%_drvs%% %%i
if not defined _drvs echo Windows not found!& goto quit
echo List of Windows:
echo -------------------------------------------
for %%i in (%_drvs%) do echo %%i:\Windows
echo -------------------------------------------
set drv=& set /p "drv=Enter drive letter: "
echo/
if not exist %drv%:\%sys% echo Windows not found!& goto quit
reg load HKLM\TMP %drv%:\%sys%|| goto quit
reg add "HKLM\TMP\ControlSet001\Control\ComputerName\ComputerName" /v ComputerName /t REG_SZ /d "%var%" /f
reg add "HKLM\TMP\ControlSet001\Control\ComputerName\ActiveComputerName" /v ComputerName /t REG_SZ /d "%var%" /f
reg add "HKLM\TMP\ControlSet001\Services\Tcpip\Parameters" /v Hostname /t REG_SZ /d "%var%" /f
reg add "HKLM\TMP\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d "%var%" /f
reg unload HKLM\TMP
goto quit
:quit
echo/
pause