InfoPE (аналог BGInfo)

ENVI^ forcelocal=1
ENVI &nc=1
FIND --pid &pd,
MSTR &I1=<1>%&pd%
MSTR &T1=<2>%&pd%
MSTR &nc=<3>%&pd%
SET &ll=-100
WAIT 250
SCRN ScrW,ScrH
CALC l=%ScrW%-300
ENVI zp=,
ww
_SUB ww,L-100T-100W1H1,,
call win
_end
_SUB win,L%l%T20W265H700,InfoPE,,shell32.dll#221,#10  //:0x7C7C7B,
ENVI @win.bkcolor = 0x7C7C7B
MENU ,Hide,ENVI @win.Visible=0
MENU ,Show,ENVI @win.Visible=1
MENU ,Exit,exit 2
ENVI @this.FONT=8:Tahoma
FIND MEM=?,FullR
REGI $HKEY_LOCAL_MACHINE\HARDWARE\DESCRIPTION\System\CentralProcessor\0\ProcessorNameString,pr
REGI $HKEY_LOCAL_MACHINE\HARDWARE\DESCRIPTION\System\BIOS\BaseBoardManufacturer,mp
REGI $HKEY_LOCAL_MACHINE\HARDWARE\DESCRIPTION\System\BIOS\BaseBoardProduct,mpp
LABE -left ,L10T10W280H12,%mp% %mpp%,,0xFFFFFF#0x7C7C7B,7
LABE -left ,L10T27W280H12,%pr%,,0xFFFFFF#0x7C7C7B,7
PBAR cpu,L10T44W215H15,0
TIME ,500, CALL proc
CALL proc
LABE -left L10,L10T70W100H15,RAM : %FullR% Mb,,0xFFFFFF#0x7C7C7B,
LABE -left L20,L150T70W100H21,,*,0xFFFFFF#0x7C7C7B,
LABE -left L11,L10T90W220H15,- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - ,,0x33FFFF#0x7C7C7B,
envi n=1
FDRV *ab DrvAll= *:
FORX * %DrvAll%,CurDsk,
{* FORM V= %CurDsk%
SET AllDrv= %AllDrv% %CurDsk%
TEAM FIND %CurDsk%\=?,f1|IFEX %CurDsk%\=?,f2
CALC #s1=((%f1%-%f2%)*100)/%f1%
TEAM CALC f1=%f1%/1M|CALC f2=%f2%/1M|ENVI g1=Mb|ENVI g2=Mb
IFEX $%f1%>1024,TEAM CALC f1=%f1%/1024|ENVI g1=Gb
IFEX $%f2%>1024,TEAM CALC f2=%f2%/1024|ENVI g2=Gb
IFEX $%f1%>1024,TEAM CALC f1=%f1%/1024|ENVI g1=Tb
IFEX $%f2%>1024,TEAM CALC f2=%f2%/1024|ENVI g2=Tb
TEAM MSTR f1=0,4,%f1%|MSTR f2=0,4,%f2%
TEAM CALC m1=%n%*35+70|CALC m2=%n%*35+85
TEAM RSTR &&te=1,%f1%|FIND $%&te%=.,LSTR f1=3,%f1%
TEAM RSTR &&te=1,%f2%|FIND $%&te%=.,LSTR f2=3,%f2%
TEAM ENVI tx= LABE -left L%n%,L10T%m1%W108H15, %CurDsk% %f1% %g1%,,0xFFFFFF#0x7C7C7B,|%tx%
TEAM ENVI tx= LABE -right L%n%,L108T%m1%W108H15,free %f2% %g2% ,,0xFFFFFF#0x7C7C7B,|%tx%
TEAM ENVI p=PBAR Pbar%n%,L10T%m2%W215H8,%s1%|%p%
IFEX $%s1%>90,ENVI @Pbar%n%.percent=%s1%::0x0F1CEA!ENVI @Pbar%n%.percent=%s1%::0x00ff00
IFEX $%f1%=0,ENVI @Pbar%n%.percent=100::0x0ffffd
CALC m5=%m2%-4
FORM td,t=%CurDsk%
ENVI typ=%td% %t%
FIND $%td%=DRIVE_FIXED,IMAG im%n%,L236T%m5%W15H15,#3
FIND $%td%=DRIVE_REMOVABLE,IMAG im%n%,L236T%m5%W15H15,#8
FIND $%td%=DRIVE_USBFLASH,IMAG im%n%,L236T%m5%W15H15,#7
FIND $%td%=DRIVE_USBDISK,IMAG im%n%,L236T%m5%W15H15,#8
IFEX $%t%<=0,IMAG im%n%,L236T%m5%W15H15,#10
FIND $%td%=DRIVE_CDROM,IMAG im%n%,L236T%m5%W15H15,#11
FIND $%td%=DRIVE_RAMDISK,IMAG im%n%,L236T%m5%W15H15,#10
CALC n=%n%+1
}
ver
CALC wi=%m2%+25
ENVI @win.pos=:::%wi%
HKEY Ctrl+Alt+I,TEAM KILL @ww|KILL \
_END
_SUB proc
FIND --pid &pd,
MSTR &I2=<1>%&pd%
MSTR &T2=<2>%&pd%
CALC #&I21=%&I2% - %&I1%
CALC #&T21=%&T2% - %&T1%
CALC &P= 100 - 100 * %&I21% / %&T21% / %&nc% ##1
FIND $%P%=-0.0, SET P=0
IFEX $%P%<0, EXIT
IFEX $%ll%=%P%, EXIT
SET ll=%P%
ENVI @cpu=%&P%;%&P%%%
ENVI @cpu.percent=%&P%::0xff
ENVI &I1=%&I2%
ENVI &T1=%&T2%
IFEX MEMU=?,&MemU
IFEX MEMA=?,&MemA
CALC &vu= 100 - 100 * %MemU% / %MemA% ##1
ENVI @L20=busy: %&vu%%
_END
_SUB ver
CALC m4=%n%*35+65
LABE -left L11,L10T%m4%W220H15,- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  ,,0x33FFFF#0x7C7C7B,
CALC m=%n%*35+70
CALC m2=%m%
envi q=1
forx \Windows\System32\cmd.exe,cm,0,
{ENVI ?v=FVER,%cm%
lstr r=2,%cm%
LSTR sp=3,%v%
LSTR sp2=6,%v%
mstr -delims:. c=<3>%v%
FIND $%sp%=5.0,ENVI vv=Windows XP
FIND $%sp%=6.0,ENVI vv=Vista
FIND $%sp%=6.1,ENVI vv=Windows 7
FIND $%sp%=6.2,ENVI vv=Windows 8
FIND $%sp%=6.3,ENVI vv=Windows 8.1
FIND $%sp2%=10.0.1,ENVI vv=Windows 10
FIND $%sp2%=10.0.2,ENVI vv=Windows 11
Envi ?bit=PEBIT,%r%\Windows\System32
CALC m2=%q%*20+%m%
envi lb=labe -left lab%q%,L10T%m2%W210H20,%r% %vv% %c%   %bit%,,0xFFFFFF#0x7C7C7B,
%lb%
CALC q=%q%+1
}
_END