Батники - вопросы и решения

@set @x=0; /*
@echo off
ver |>NUL find /v "5." && if "%~1"=="" cscript.exe //nologo //e:jscript "%~f0"& exit /b
chcp 1251>nul
color 70
if defined PROCESSOR_ARCHITEW6432 start %SystemRoot%\Sysnative\cmd.exe /c "%~dpnx0" %* & exit
set WinPE=& 2>nul (<%SystemRoot%\system32\config\system set /p WinPE=)
if not defined WinPE >nul 2>&1 dism|| goto runas
cls
cd /d "%~dp0"
set tdir=%tmp%\ONSE_WinPE
set lst=%tdir%\list.txt
2>nul (del /f/a/q %tdir%& rd /q/s %tdir%& md %tdir%)
for /f "tokens=3" %%a in (
'2^>nul reg query "HKLM\SYSTEM\CurrentControlSet\Control\Nls\CodePage" /v ACP'
) do >nul 2>&1 chcp %%a
set id=identifier& for /f "tokens=1 delims= " %%a in ('bcdedit.exe /enum^|find /i "идентификатор"') do set id=%%a
2>nul bcdedit.exe /enum all| find "path"| >nul find ".efi"&& set isEFI=UEFI|| set isEFI=BIOS
SetLocal EnableDelayedExpansion
:sel
set c=0& set count=0& set "cont=1"&set s=::&
set tpth=& set Bootloader=& set pth=& set name=& set var=& set "userinp="
cls
echo.
set /a c+=1&echo !c!.*Current system
set /a c+=1&echo !c!.Boot from WinPE (Bootloader)
set /a c+=1&echo !c!.Choose BCD
set /a c+=1&echo !c!.Delete selected item from BCD
for %%i in (B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%i:\boot\bcd (
set s=1
xcopy /hy %%i:\boot\bcd !tdir! 2>nul 1>&2
if !errorlevel!==0 (
set /a c+=1&set pth!c!=%%i:\boot\bcd& echo !c!.%%i: BIOS [\boot\bcd]
If exist !tdir!\bcd del /q !tdir!\bcd
))
if exist %%i:\efi\microsoft\boot\bcd ((if not defined s echo.)&set /a c+=1&set pth!c!=%%i:\efi\microsoft\boot\bcd& echo !c!.%%i: UEFI [\efi\microsoft\boot\bcd])
)
set /a c+=1&echo !c!.Выход ( {!c!} and {ENTER} )
echo.
set /p var= ^> Выберите :
FOR /L %%b IN (5,1,%c%) DO (
if "!var!"=="1" set "pth=true"
if "!var!"=="2" goto :wre
if "!var!"=="3" set Bootloader=true& goto :SetBCD
if "!var!"=="!c!" goto :quit
if "!var!"=="4" set delbcd=true& goto :SetBCD
if "!var!"=="%%b" set pth=!pth%%b!
)
if not defined var goto sel
:list
if defined pth (
set n=& set tpth=& if !var! GEQ 3 set n=true
if defined n (
if not defined name set name=bcd
2>nul del /f/a/q !tdir!\!name!
2>nul del /f/a/q !lst!
>nul xcopy /hy !pth! !tdir!& set tpth=/store !tdir!\!name!
)
cls
set s=& set i=& set p=& set "d="
for /f "tokens=1*" %%a in ('bcdedit.exe !tpth! /enum all') do ^
set "l=%%a"& if "!l:~0,11!"=="-----------" (
if defined d if defined p call :out
set s=& set i=& set p=& set "d="
) else (
if /i "%%a"=="!id!" set i=%%b
if /i "%%a"=="description" set "d=%%b"
if /i "%%a"=="path" if "%%~nb" neq "winresume" set p=true
if /i "%%a"=="kernel" set p=1
if not defined p if /i "%%a"=="device" if "%%~nb" neq "unknown" set p=true
if /i "%%a"=="FilePath" set "p="
if /i "%%a"=="systemroot" set s=1
if /i "%%a"=="winpe" if /i "%%b"=="yes" set "s="
if /i "!d!"=="Windows Recovery Environment" set WinRE=1&set guid1=!i!
if /i "!d!"=="ONSE_WinPE" If Not "!i!"=="{current}" (
bcdedit.exe !tpth! /delete !i! 2>nul 1>&2
goto list
  )
)
)
cls
if defined d if defined p call :out
if defined n call :quest
echo.
echo !cont!.Расширеные варианты загрузки
echo.
set /a cont+=1& echo !cont!.Безопасный режим
set /a cont+=1& echo !cont!.Безопасный режим с загрузкой сетевых драйверов
set /a cont+=1& echo !cont!.Безопасный режим с поддержкой командной строки
echo.
set /a cont+=1& echo !cont!.Ведение журнала загрузки
set /a cont+=1& echo !cont!.Включение видеорежима с низким разрешением (640x480)
set /a cont+=1& echo !cont!.Последняя удачная конфигурация
echo.
set /a cont+=1& echo !cont!.Отключение обязательной подписи драйверов
set /a cont+=1& echo !cont!.Отключить функцию раннего запуска антивредоносной защиты (ELAM)
set /a cont+=1& echo !cont!.Отключить автоматическую перезагрузку при отказе системы
echo.
set /a cont+=1& echo !cont!.Принудительно использовать одно ядро при загрузке
set /a cont+=1& echo !cont!.Отключить автоматическую перезагрузку
echo.
set /a cont+=1& echo !cont!.Обычная загрузка Windows (!osdef!)
echo.
set /a cont+=1& echo !cont!.Диагностика памяти
If "!WinRE!"=="1" set /a cont+=1& echo !cont!.Устранение неполадок (Windows Recovery Environment)
echo.
set /p userinp= ^> Выберите, что хотите сделать :
if not defined userinp goto sel
echo.
if "!userinp!"=="15" set guid=!guid1!
if "!userinp!"=="14" set guid={memdiag}
set s=& for /f "tokens=2 delims={}" %%a in ('bcdedit.exe /copy !guid! /d "ONSE_WinPE"') do set guid={%%a}
if "!userinp!"=="1" set s=advancedoptions true
if "!userinp!"=="2" set s=safeboot minimal
if "!userinp!"=="3" set s=safeboot network
if "!userinp!"=="4" (
  bcdedit.exe /set !guid! safeboot minimal
  bcdedit.exe /set !guid! safebootalternateshell yes
)
if "!userinp!"=="5" (
  bcdedit.exe /set !guid! sos on
  bcdedit.exe /set !guid! bootlog yes
)
if "!userinp!"=="6" set s=vga on
if "!userinp!"=="7" set s=lastknowngood on
if "!userinp!"=="8" (
  bcdedit.exe /set !guid! testsigning on
  bcdedit.exe /set !guid! nointegritychecks on
  bcdedit.exe /set !guid! loadoptions DISABLE_INTEGRITY_CHECKS
)
if "!userinp!"=="9" set s=disableelamdrivers yes
if "!userinp!"=="10" set s=nocrashautoreboot on
if "!userinp!"=="11" set s=onecpu on
if "!userinp!"=="12" (
  bcdedit.exe /set !guid! recoveryenabled no
  bcdedit.exe /set !guid! bootstatuspolicy ignoreallfailures
)
if "!userinp!"=="13" for /f "skip=3 tokens=1" %%a in ('bcdedit.exe /enum !guid!') do (
set p=& for %%i in (
!id! device path description inherit osdevice systemroot
) do if /i %%a==%%i set p=1
if not defined p bcdedit.exe /deletevalue !guid! %%a
)
if "!userinp!"=="15" goto reboot
if "!userinp!"=="14" goto reboot
if defined s bcdedit.exe /set !guid! !s!
bcdedit.exe /displayorder !guid! /remove
)
:wre
if not defined pth (
cls
echo.
echo  Boot from WinPE
goto bootPE
)
goto reboot
:bootPE
call :SetBCD
if not defined fname goto sel
set sdi=& for /f "tokens=1*" %%a in ('bcdedit.exe /enum all') do ^
if /i "%%a"=="!id!" (set i=%%b) else if /i "%%a"=="ramdisksdipath" call set sdi=!i!
if defined sdi goto next
for /f "tokens=2 delims={}" %%a in ('bcdedit.exe /create {ramdiskoptions}') do set sdi={%%a}
bcdedit.exe /set !sdi! ramdisksdidevice partition=C:
bcdedit.exe /set !sdi! ramdisksdipath \Windows\System32\boot.sdi
reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce" /v "*2" /t REG_SZ /d "bcdedit /delete {ramdiskoptions} /f" /f
:next
for /f "tokens=2 delims={}" %%a in ('bcdedit.exe /create /d "ONSE_WinPE" /application osloader') do set guid={%%a}
set i=bcdedit.exe /set !guid!
  %i% device ramdisk=!fname!,!sdi!
  %i% osdevice ramdisk=!fname!,!sdi!
  %i% systemroot \windows
  %i% winpe yes
  %i% nx optin
  %i% detecthal yes
  %i% testsigning on
  %i% nointegritychecks on
)
:reboot
if not defined n reg add "HKLM\Software\Microsoft\Windows\CurrentVersion\RunOnce" /v "*1" /t REG_SZ /d "bcdedit /delete !guid!" /f 2>nul 1>&2
bcdedit.exe !tpth! /bootsequence !guid! 2>nul 1>&2
cls
echo.
echo.
set /p inp= ^> Перезагрузить этот компьютер прямо сейчас? (нажмите 1 и {ENTER} ) ^
                                                       или ^
                                                             вернуться в главное меню                  ( {ENTER} ):
if "!inp!"=="1" shutdown.exe -r -f -t 05
if "!inp!"=="" goto sel
:quit
2>nul (rd /q/s %tdir%)
Exit
:out
if !i!=={bootmgr} exit /b
set /a count+=1
::echo !i!
set cur= & if !i!=={current} set guid=!i!&set cur=*
if !i!=={default} set guid=!i!&set cur=*
set vars=& if defined s set "vars=...  >"
::echo !cur!!d!!vars!
if defined cur if defined s set osdef=!cur!!d!!vars!
if !var! GEQ 3 set g=!count!.!cur!!d!!vars! !i!
if defined g echo !g!>>%lst%
exit /b
:quest
for /f "tokens=1 delims={" %%a in (!lst!) do echo %%a
echo.
set skip=&set /p skip= ^> Выберите пункт :
if not defined skip goto sel
set /a skip=%skip%-1
set skip=& if %skip% gtr 0 set skip=skip=%skip%
set gud=& for /f "%skip% tokens=1* delims={" %%a in (%lst%) do call set "nam=%%a"&call set gud={%%b& goto :next !gud! !nam!
:next
set guid=!gud!& set "idname=!nam!"
if defined n set tpth=& if defined pth set tpth=/store !pth!
if defined delbcd goto DellBCD !idname!
goto reboot
:SetBCD
>%tdir%\f1.vbs echo WScript.Echo CreateObject("WScript.Shell").Exec("mshta.exe ""about:<input type=file id=FILE><script>FILE.click();new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).WriteLine(FILE.value);close();resizeTo(0,0);</script>""").StdOut.ReadLine
set fname=& set fname1=& for /f "delims=" %%a in ('cscript.exe //nologo %tdir%\f1.vbs') do (
set fname1="%%~a"& set fname=[%%~da]"%%~pnxa"& set "name=%%~nxa"
if not defined Bootloader if not defined delbcd if /i "%%~xa"==".wim" (exit /b !fname!) else goto bootSec
)
set pth=!fname1!
if not defined pth goto sel
goto list
:DellBCD
cls
echo.
echo Удаляю пункт: !idname!
echo.
rem bcdedit.exe !tpth! /delete !guid! /f
TIMEOUT /T 5 /NOBREAK >nul
goto sel
:bootSec
if "!isEFI!"=="UEFI" (
echo  Ошибка: загрузчик не поддерживается в UEFI
TIMEOUT /T 5 /NOBREAK >nul
goto sel
)
if defined n set "tpth="
for /f "tokens=2 delims={}" %%a in ('bcdedit.exe !tpth! /create /d "ONSE_WinPE" /application bootsector') do set guid={%%a}
for /f "tokens=1,2 delims=[]" %%a in ("!fname!") do (
bcdedit.exe !tpth! /set !guid! device partition=%%a >nul 2>&1
bcdedit.exe !tpth! /set !guid! path %%b >nul 2>&1
)
goto reboot
:runas
set vbs=%tmp%\f.vbs
>%vbs% echo WScript.CreateObject("Shell.Application").ShellExecute "%comspec%", "/c cd /d ""%~sdp0"" && %~snx0", "", "runas", 1
cscript //nologo %vbs%
del /q %vbs%
:: Эту строку не трогать. Ниже ничего не писать!!!
*/new ActiveXObject('Shell.Application').ShellExecute (WScript.ScriptFullName,'Admin','','runas',1);