Мелкие полезности для себя

@echo off
mode con cols=85 lines=5
SetLocal EnableExtensions EnableDelayedExpansion
CD /d "%~dp0"
echo ... Notepad++
set "h1=https://github.com/notepad-plus-plus/notepad-plus-plus/releases"
set "d1=download/.*[.]exe"
set "w1=npp.Installer-x86.exe"
set "w2=npp.Installer-x64.exe"
echo.?> "%~dp0alarm.txt"
("%~dp0..\Scripts\http2cli.exe" "%h1%" 2| findstr /R /C:"%d1%") >"%~dp0down.txt"
for %%a in ("%~dp0down.txt") do set size=%%~za
if %size%==0 goto 1
<"%~dp0down.txt" (for /f "tokens=1* delims=[]" %%a in ('find /n /v ""') do set "s%%a=%%b")
FOR /F "tokens=2 delims=+++" %%a in ("%s3%") do set "g1=https://github.com%%a"
FOR /F "tokens=2 delims=+++" %%a in ("%s5%") do set "g2=https://github.com%%a"
FOR /F "tokens=7 delims=/" %%a in ("%g1%") do set "f=%%a"
set f=%f:*v=%
if exist "%~dp0%w1%" ( for %%a in ("%~dp0%w1%") do set "fsize=%%~za" ) else ( set "fsize=0" )
("%~dp0..\Scripts\netsize.exe" "%g1%") >"%~dp0down.txt"
Set /p nsize=<"%~dp0down.txt"
if %fsize% NEQ %nsize% (
"%~dp0..\Scripts\axel.exe" "%g1%" -k -a -n 8 -o "%~dp0%w1%.~"
for %%a in ("%~dp0%w1%.~") do set size=%%~za
if !size!==0 goto 1
del "%~dp0%w1%" /q
ren "%~dp0%w1%.~" "%w1%"
echo %date%> "%~dp0date.txt"
)
if exist "%~dp0%w2%" ( for %%a in ("%~dp0%w2%") do set "fsize=%%~za" ) else ( set "fsize=0" )
("%~dp0..\Scripts\netsize.exe" "%g2%") >"%~dp0down.txt"
Set /p nsize=<"%~dp0down.txt"
if %fsize% NEQ %nsize% (
"%~dp0..\Scripts\axel.exe" "%g2%" -k -a -n 8 -o "%~dp0%w2%.~"
for %%a in ("%~dp0%w2%.~") do set size=%%~za
if !size!==0 goto 1
del "%~dp0%w2%" /q
ren "%~dp0%w2%.~" "%w2%"
echo %date%> "%~dp0date.txt"
)
("%~dp0..\Scripts\filever.exe" /A /D "%~dp0%w1%") >"%~dp0down.txt"
FOR /F "usebackq tokens=4" %%a in ("%~dp0down.txt") do set f=%%a
echo %f%> "%~dp0version.txt"
del "%~dp0alarm.txt" /q
:1
del "%~dp0down.txt" /q
del "%~dp0*.~" /q

if defined ProgramW6432 (
set file=npp.Installer-x64.exe
) else (
set file=npp.Installer-x86.exe
)
start /wait %file% /S