[Quote]

    wadimus
  • 14910
  • Longevity: 5 years 8 months
  • Posts: 530
  • REPUTATION:68

    [+] [-]
dimo70, тебе в коллекцию ..
DDU (Display Driver Uninstaller)
батник получения Sfx-ехе-файла DDU.exe ну очень хитро-выделанный .. надеюсь, будет применим и для следующих версий (немножжко откомментил его):
@echo off
mode con cols=85 lines=5
SetLocal EnableExtensions EnableDelayedExpansion
CD /d "%~dp0"
echo ... Display Driver Uninstaller (DDU)
set "h1=https://www.wagnardsoft.com"
set "d1=[0-9]-released"
set "w1=DDU.exe"
echo.?> "%~dp0alarm.txt"
:: по начальной ссылке ищем ссылку на страницу, где есть ссылки на страницу, где есть прямые ссылки :)
("%~dp0..\Scripts\http2cli.exe" "%h1%" 2| findstr /R /C:"%d1%") >"%~dp0down.txt"
for %%a in ("%~dp0down.txt") do set size=%%~za
if %size%==0 goto 1
<"%~dp0down.txt" (for /f "tokens=1* delims=[]" %%a in ('find /n /v ""') do set "s%%a=%%b")
FOR /F "tokens=6 delims=+++" %%a in ("%s1%") do set "h1=https://www.wagnardsoft.com%%a"
:: нашли страницу, где есть ссылки на страницу, где есть нужный нам ехе-файл
set "d1=t=[0-9][0-9]"
("%~dp0..\Scripts\http2cli.exe" "%h1%" 2| findstr /R /C:"%d1%") >"%~dp0down.txt"
for %%a in ("%~dp0down.txt") do set size=%%~za
if %size%==0 goto 1
<"%~dp0down.txt" (for /f "tokens=1* delims=[]" %%a in ('find /n /v ""') do set "s%%a=%%b")
FOR /F "tokens=2 delims=+++" %%a in ("%s1%") do set "h1=%%a"
:: на этой странице ищем прямую ссылку на нужный нам ехе-файл
set "d1=[.]exe"
("%~dp0..\Scripts\http2cli.exe" "%h1%" 2| findstr /R /C:"%d1%") >"%~dp0down.txt"
for %%a in ("%~dp0down.txt") do set size=%%~za
if %size%==0 goto 1
<"%~dp0down.txt" (for /f "tokens=1* delims=[]" %%a in ('find /n /v ""') do set "s%%a=%%b")
FOR /F "tokens=4 delims=+++" %%a in ("%s1%") do set "g1=%%a"
:: и на этой-же странице ищем версию нужного нам ехе-файла
set "d1=[0-9] Released"
("%~dp0..\Scripts\wget.exe" -q -O- "%h1%" | findstr /R /C:"%d1%") >"%~dp0down.txt"
for %%a in ("%~dp0down.txt") do set size=%%~za
if %size%==0 goto 1
<"%~dp0down.txt" (for /f "tokens=1* delims=[]" %%a in ('find /n /v ""') do set "s%%a=%%b")
FOR /F "tokens=5 delims= " %%a in ("%s1%") do set "f=%%a"
set "f=%f:~1%"
:: версию нашли и почистили её от лишних символов
:: далее, как обычно, скачиваем ехе-файл
if exist "%~dp0%w1%" ( for %%a in ("%~dp0%w1%") do set "fsize=%%~za" ) else ( set "fsize=0" )
("%~dp0..\Scripts\netsize.exe" "%g1%") >"%~dp0down.txt"
Set /p nsize=<"%~dp0down.txt"
if %fsize% NEQ %nsize% (
cls
echo. %w1%
echo.
"%~dp0..\Scripts\aria2c.exe" "%g1%" --check-certificate=false --console-log-level=error --file-allocation=none --allow-overwrite=true -x8 -s8 -o "%w1%.~"
for %%a in ("%~dp0%w1%.~") do set size=%%~za
if !size!==0 goto 1
del "%~dp0%w1%" /q
ren "%~dp0%w1%.~" "%w1%"
echo %date%> "%~dp0date.txt"
)
echo %f%> "%~dp0version.txt"
del "%~dp0alarm.txt" /q
:1
del "%~dp0down.txt" /q
del "%~dp0*.~" /q
Exit /B
DDU.exe - искомый нам Sfx-ехе-файл
version.txt - в первой строке - версия (18.0.5.3)
date.txt - дата получения DDU.exe (не дата создания его, а дата скачивания!)

[Quote]

    dimo70
  • 17296
  • Longevity: 4 years 8 months
  • Posts: 3511
  • REPUTATION:41

    [+] [-]
  • Location: BG
wadimus, aa

[Quote]

    dimo70
  • 17296
  • Longevity: 4 years 8 months
  • Posts: 3511
  • REPUTATION:41

    [+] [-]
  • Location: BG
wadimus, тут сложно разобраться с ins.bat. Хотел автоматом стартануть DDU, но так связали архив с версию, что батника трудно настроить распаковать, а потом запустить екзешник из папку проэкта.
DDU_Online.exe

[Quote]

    wadimus
  • 14910
  • Longevity: 5 years 8 months
  • Posts: 530
  • REPUTATION:68

    [+] [-]
dimo70, с архивами, простыми портабелями, простыми ехе-файлами поступаю просто:
копирую (распаковываю) их на рабочий стол (конкретного пользователя) в определённую папку
for /f "tokens=2*" %%a in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Desktop') do set folder=%%~b
"%~dp0..\Scripts\7z.exe" x "DDU.exe" -y -o"%folder%\-Portable-\"
set f4=3
cscript //nologo "%~dp0..\Scripts\popup.vbs" "Смотри папку -Portable- на Рабочем столе" "Архив распакован на Рабочий стол" %f4%
в первой строке получаю папку Рабочего стола пользователя
далее распаковываю Sfx-exe-файл DDU.exe простым 7z.exe
после чего вывожу окно с кнопкой Ok на 3 сек
popup.vbs:
on error resume next
msg = Wscript.Arguments(0)
Title = Wscript.Arguments(1)
sec = Wscript.Arguments(2)
WScript.CreateObject("WScript.Shell").Popup msg, sec, Title, vbOkOnly + vbInformation

[Quote]

    dimo70
  • 17296
  • Longevity: 4 years 8 months
  • Posts: 3511
  • REPUTATION:41

    [+] [-]
  • Location: BG
wadimus, извини дружище, но это лишнее. Лучше подумать как разархивировать и запустить саму утилиту автоматом (если конечно возможно такое вообще сделать батником, так как там все версии обвязано) aa

[Quote]

    wadimus
  • 14910
  • Longevity: 5 years 8 months
  • Posts: 530
  • REPUTATION:68

    [+] [-]
dimo70, аналогичная задача по скачиванию SDI-пакетов .. Snappy Driver Installer Origin (от Glenn Delahoy)
скачиваем архив типа SDIO.zip, а в нём уже есть папка типа SDIO_1.4.1.675, и в этой папке нужные нам файлы с подпапками.
как решал проблему, часть батника с комментами:
..
:: распаковываем архив в корень sdi_o
"%~dp07z.exe" x "%~dp0..\%sdi_o%\%w2%" -y -o"%~dp0..\%sdi_o%"
:: проблема такая .. в архиве есть начальный каталог, типа SDIO_1.4.1.675 (и в нём уже содержатся нужные нам файлы)
:: все нужные нам файлы при разархивации будут не в корне, а в папке SDIO_1.4.1.675
:: поэтому делаем так - все файлы и папки перемещаем из папки SDIO_1.4.1.675 (SDI*) в корень (на каталог ниже)
:: переместили и тут же удалили пустую папку
:: в итоге получим все файлы в корне sdi_o с исходной структурой
for /f %%a in ('dir /a:d /b "%~dp0..\%sdi_o%\SDI*"') do (
    XCOPY "%~dp0..\%sdi_o%\%%a" "%~dp0..\%sdi_o%" /H /E /G /Q /R /Y
    rmdir "%~dp0..\%sdi_o%\%%a" /s /q
)
:: архив SDIO.zip отработан, его удаляем
del /f /q "%~dp0..\%sdi_o%\%w2%"
..

Page 73 of 73


Display posts:    

Current time is: 12-Aug 11:09

All times are UTC + 3


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum