SDI-tool: updater

@echo off
cd /d "%~dp0"
2>nul rd /q/s tmp& md tmp
set unzip=^>tmp\tst.vbs echo With CreateObject("Shell.Application") .NameSpace(WScript.Arguments(0)).CopyHere(.NameSpace(WScript.Arguments(1)).Items) End With^& cscript.exe tmp\tst.vbs
if exist bin\aria2c.exe goto next
certutil.exe -urlcache -f -split "https://github.com/aria2/aria2/releases/download/release-1.35.0/aria2-1.35.0-win-32bit-build1.zip" tmp\a.zip
md bin& %unzip% "%CD%\tmp" "%CD%\tmp\a.zip"
for /r %%i in (aria2c.ex?) do move "%%~i" bin
bin\aria2c.exe "https://getspace.cloud/cloud/s/KTWHwQN9cn8H6Kt/download?path=/SDI/&files=dht.dat" -d bin
:next
bin\aria2c.exe http://driveroff.net/SDI_Update.torrent -d tmp --follow-torrent=false
>tmp\s bin\aria2c.exe -S tmp\SDI_Update.torrent
if not exist ..\SDI_R*.exe call :renew
for %%i in (..\SDI_R*.exe) do set sdi.exe=%%~nxi
>tmp\d dir /b ..\drivers\*.7z
setlocal EnableDelayedExpansion
if /i "%1"=="only" (
for /f "tokens=1,2 delims=| " %%a in ('^<tmp\s find /i ".7z"') do ^
for /f %%i in (tmp\d) do (
set var=%%~ni
set var=!var:~0,-5!
set src=%%~nb
set src=!src:~0,-5!
if /i !var!==!src! if /i %%~ni neq %%~nb set files=!files!,%%a& >>tmp\t echo %%~nxb
)) else ^
for /f "tokens=1,2 delims=| " %%a in ('^<tmp\s find /i ".7z"') do >nul find /i "%%~nxb" tmp\d||(set files=!files!,%%a& >>tmp\t echo %%~nxb)
endlocal& set files=%files%
if not defined files (
>tmp\t echo No driver pack updates found.
goto logging
)
bin\aria2c.exe tmp\SDI_Update.torrent -d tmp --seed-time=0 --file-allocation=trunc --select-file=%files:~1% --dht-file-path=bin\dht.dat --bt-request-peer-speed-limit=1M --stop=10800
for /r %%i in (DP_*.7z) do set "pth=%%~dpi"
for /f %%a in (tmp\t) do ..\%sdi.exe% -7z t "%pth%%%a"&& (
set var=%%~na
call set var=%%var:~0,-5%%
call del /q ..\drivers\%%var%%*.7z
move "%pth%%%a" ..\drivers
)|| >>tmp\err echo ERROR: %%a
if defined var (
pushd ..\indexes
del /q/s *.bin
cd ..
%sdi.exe% -nogui -reindex -nologfile -preservecfg
popd
)
:logging
>nul find /i "%sdi.exe%" tmp\s|| call :renew
>>log.txt (
echo --- %date% ------------------------------
if defined fname echo %fname%
type tmp\t
if exist tmp\err type tmp\err
echo ---------------------------------------------
echo/
)
rd /q/s tmp
exit
:renew
for /f "tokens=2 delims=|" %%a in ('^<tmp\s findstr /irc:"SDI_R[0-9]*.exe"') do set fname=%%~na.zip
bin\aria2c.exe http://sdi-tool.org/releases/%fname% -d tmp
md tmp\new& %unzip% "%CD%\tmp\new" "%CD%\tmp\%fname%"
del /q ..\SDI_*.*
robocopy.exe /e /move "%CD%\tmp\new" ..