[Цитировать]

    cartmenezz
  • 1384
  • Стаж: 8 лет 6 месяцев
  • Сообщений: 526
  • Репутация:14

    [+] [-]
  • Откуда: Калининград
Blindscanner - отличная прога, которая дает возможность расшарить сканнер по локальной сети. Настраивается не сложно, работает четко, по крайней мере в моем случае с МФУ Canon MF3010 сложностей не возникло. Теперь наконец-то можно не только печатать, но и сканировать с другого ПК (для печати принтер расшарен средствами Windows, прога расшаривает только сканнер).
НО! кое-что мне все-таки не понравилось - прога не создает подпапки с текущей датой (как это делает стандартная утиллита от Canon), неудобно, все в кучу. Единственное, можно настроить чтобы дата была в имени файла, но это тоже не то.-Как выяснилось, есть возможность использовать клиент из командной строки - ссылка

справка BlindScannerCLI

Usage: BlindScannerCLI [options] <server> <scanner> <filename>
Share TWAIN scanner over a local area network
Options:
  --port <port>           Remote port (default 8910 used if the option is
                          ommited)
  -a, --adf               Use automatic document feeder (if available)
  -d, --duplex            Double sided scanning (if available)
  -p, --path <path>       Scan and save files into <path>
  -f, --format <format>   File format (bmp, jpg, png, tiff, pdf)
  -m, --mode <mode>       Color mode (bw, grayscale, color)
  -r, --resolution <dpi>  Resolution
  --mp, --multipage       Create multipage document. The flag is ignored if
                          format is other than "pdf" or "tiff"
  -?, -h, --help          Displays this help.
  -v, --version           Displays version information.
Arguments:
  server                  Server name or IP address
  scanner                 Scanner name
  filename                Destination file name template
                          <D> - is replaced by the date in the format YYYY-MM-DD
                          <T> - is replaced by the time in the format HH-MM-SS
                          <#>, <##>, ... - Is replaced by a sequence number with
                          a leading zero(s) (01, 02, ...) or without
-Сделал для себя батник:
@echo off
TITLE -BlindScanner-
for /f %%a in ('echo prompt $H ^| cmd') do set "del_char=%%a"
set "Blind=C:\Program Files (x86)\BlindScanner\BlindScannerCLI.exe"
:: Main folder for scans
set "Dir=%UserProfile%\Pictures\Scans"
:: Delete empty folders in Main folder
FOR /D %%a in ("%Dir%\*") do rd /q "%%a" 2>nul
:: ScanDir - subfolder with current date for saving scans
FOR /F "tokens=1-3 delims=." %%a in ("%DATE%") do set "ScanDir=%Dir%\%%c-%%b-%%a"
if NOT Exist "%ScanDir%" MD "%ScanDir%"
:: Server name or IP address
set "server=192.168.0.111"
:: Scanner name
set "scanner=Canon MF3010"
:: File format (bmp, jpg, png, tiff, pdf)
set "format=jpg"
:: Color mode (bw, grayscale, color)
set "mode=color"
set "mode_=Цвет          "
:: Resolution (dpi)
set "DPI=200"
:start
cls
:: Destination file name
set "fName=scan"
echo.
echo   ЗАПУСК СКАНИРОВАНИЯ ^>
echo   ===========================================================================
echo   ИСПОЛЬЗОВАТЬ СТАНДАРТНОЕ ИМЯ ФАЙЛА:       ВВЕСТИ ДРУГОЕ ИМЯ ФАЙЛА:
echo   1 = Скан в JPG, одна страница             4 = Скан в JPG, одна страница
echo   2 = Скан в PDF, одна страница             5 = Скан в PDF, одна страница
echo   3 = Скан в PDF, несколько страниц         6 = Скан в PDF, несколько страниц
echo   ===========================================================================
echo.
echo   ДОП. ПАРАМЕТРЫ ^>
echo   ===========================================================================
echo   РЕЖИМ      : %mode_%   [11 = Цветное, 12 = Ч/Б, 13 = Оттенки серого]
echo   РАЗРЕШЕНИЕ : %DPI% dpi          [100 = 100, 200 = 200, 300 = 300, 400 = 400 ]
echo   ===========================================================================
echo.
echo.
set var=& set /p "var=%del_char%  ВВОД: "|| GoTo :start
if "%var%"=="666" start "" "C:\Program Files (x86)\BlindScanner\BlindScanner.exe"& exit
if "%var%"=="1" set "format=jpg"& GoTo :SCAN
if "%var%"=="2" set "format=pdf"& GoTo :SCAN
if "%var%"=="3" set "format=pdf --mp"& GoTo :SCAN
if "%var%"=="4" set "format=jpg"& set /p "fName=%del_char%  ВВЕДИТЕ ИМЯ ФАЙЛА: "& GoTo :SCAN
if "%var%"=="5" set "format=pdf"&set /p "fName=%del_char%  ВВЕДИТЕ ИМЯ ФАЙЛА: "& GoTo :SCAN
if "%var%"=="6" set "format=pdf --mp"&set /p "fName=%del_char%  ВВЕДИТЕ ИМЯ ФАЙЛА: "& GoTo :SCAN
if "%var%"=="11" set "mode=color"& set "mode_=Цвет          "& GoTo :start
if "%var%"=="12" set "mode=bw"& set "mode_=Ч/Б           "& GoTo :start
if "%var%"=="13" set "mode=grayscale"& set "mode_=Оттенки серого"& GoTo :start
if "%var%"=="100" set "DPI=100"& GoTo :start
if "%var%"=="200" set "DPI=200"& GoTo :start
if "%var%"=="300" set "DPI=300"& GoTo :start
if "%var%"=="400" set "DPI=400"& GoTo :start
GoTo :start
:SCAN
cls
echo.
for /f %%a in ("%format%") do set "format_=%%a"
if "%format%"=="pdf --mp" (set "format__=несколько страниц") ELSE (set "format__=одна страница")
echo  ["%fName%.%format_%"] [%format__%] [%mode%] [%DPI% dpi]
echo.
"%Blind%" -f %format% -m %mode% -r %DPI% -p "%ScanDir%" %server% "%scanner%" "%fName%"
IF "%var%"=="3" (echo.& echo  Нажмите [ENTER] для скана следующей страницы ^(или закройте это окно для выхода^)& 1>nul pause& GoTo :SCAN)
IF "%var%"=="6" (echo.& echo  Нажмите [ENTER] для скана следующей страницы ^(или закройте это окно для выхода^)& 1>nul pause& GoTo :SCAN)
GoTo :start
* При открытии удаляет пустые подпапки в родительской папке со сканами (порой такие имеются)
* В родительской папке создается подпапка с текущей датой, в формате ГГГГ-ММ-ДД, сохранение будет в нее
* в основном меню несколько вариантов сканирования: JPG, PDF, PDF с несколькими страницами.. плюс эти же варианты, но с введением своего имени файла (по умолчанию имя файла "scan")
* так же отображаются доп параметры:
Режим: Цвет (можно поменять на Ч/Б и Оттенки серого)
Разрешение: 200 dpi (можно поменять на 100,300,400)
* Никакого автоподатчика и двустроннего сканирования у нашего МФУ нет, поэтому этих параметров не добавлял, так же и с другим форматами файла (TIFF,PNG) - не добавлял, так как не требуется-Подготовка:
* Редактировать в кодировке "866 (OEM - русская)"
* изначально нужно изменить в скрипте некоторые параметры на свои:
IP сервера (или имя сервера):
set "server=192.168.0.111"
Имя сканнера:
set "scanner=Canon MF3010"
Так же нужно проверить путь до BlindScannerCLI.exe:
set "Blind=C:\Program Files (x86)\BlindScanner\BlindScannerCLI.exe"
Каталог для сохранения сканов:
set "Dir=%UserProfile%\Pictures\Scans"
Возможно вы захотите сменить имя файла по умолчанию, разрешение, режим цвета..-Использование:
* Запустили скрипт
* Ввели номер варианта сканирование (от 1 до 6), нажали Enter
* Если не устраивает значие DPI или Режим цвета по умолчанию - ввели номер пункта для изменения, нажали Enter, потом ввели номер варианта сканирования, и еще раз Enter
Например: если нужно отсканировать в разрешении 300 DPI в Ч/Б режиме и сохранить в PDF - вводим 300 , Enter, вводим 12, Enter, вводим 2, Enter - сканирование пошло
* По оканчании сканирования будет возврат в основное меню, при этом измененые параметры DPI и Режим теми что вы вводили (кроме имени файла, оно снова пропишется стандартное - "scan")
* Если выбрали сканирование в PDF в многостраничном режиме (пункты 3 и 6), то по окончании сканирования будет предложено нажать Enter для сканирования следующей страницы (запись будет в тот же файл), для выхода просто закрываем окно консоли-

Скриншоты




Видео

-Скачать: ссылка

[Цитировать]

    dimo70
  • 17296
  • Стаж: 6 лет 3 месяца
  • Сообщений: 3990
  • Репутация:26

    [+] [-]
  • Откуда: BG
cartmenezz, спасибо за труды. Хорошо получилось и наверняка пригодиться. ay
Я несколько раз уже что то такое искал для шеринг скенера и не успевал, вот сейчас уже решение есть. aa

_________________
Подпись отключена за нарушение правил форума

[Цитировать]

    cartmenezz
  • 1384
  • Стаж: 8 лет 6 месяцев
  • Сообщений: 526
  • Репутация:14

    [+] [-]
  • Откуда: Калининград
dimo70, aa
прога сама по себе хороша и удобна, интерфейс дружелюбный. если б не сортировка по папкам, не заморачиваться бы. хотя, через скрипт, лично мне, все равно удобнее (даже если забыть про папки) - часто нужно как-то "обозвать файл", в скрипте это имя сбрасывается на стандартное перед следующим сканированием, плюс ввод нового имени как по мне быстрее.. просто бывало что сканировали сохраняя со специфическим именем, и потом просто закрывали прогу, а в следующий раз (уже возможно другой человек) этого не заметили и сразу запустили скан, в итоге потом смотришь на название файла и думаешь "это что?" )) конечно почти сразу понимаешь в чем дело, переименовываешь, но все равно это потери времени. А в скрипте, если ты ввел другое имя - оно только на текущее сканирование, по мне так лучше.
так что я в принципе доволен, хотя на работе пара человек и напугалась от вида командной строки))

[Цитировать]

    UserX
  • 667
  • Стаж: 8 лет 11 месяцев
  • Сообщений: 788
  • Репутация:32

    [+] [-]
86371хотя на работе пара человек и напугалась от вида командной строки))
Вполне ожидаемо. Придётся делать графическую оболочку для своего скрипта. :)

[Цитировать]

    cartmenezz
  • 1384
  • Стаж: 8 лет 6 месяцев
  • Сообщений: 526
  • Репутация:14

    [+] [-]
  • Откуда: Калининград
UserX, ага)) хотя надеюсь до этого не дойдет))


Показать сообщения:    

Текущее время: 28-Мар 17:38

Часовой пояс: UTC + 3


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете голосовать в опросах
Вы не можете прикреплять файлы к сообщениям
Вы можете скачивать файлы