Сборка Windows Server 2019



 

[Цитировать]

Отправлено: 10-Май-2021 17:19

    Ander_73
  • 15549
  • Стаж: 7 лет 9 месяцев
  • Сообщений: 3810
  • Репутация:127

    [+] [-]
Набросал батничек для самостоятельной подготовки Windows Server 2019.
Что делает:
  • скачивает Windows Server 2019 Evaluation
  • конвертирует его в VL
  • интегрирует обновления и dotNet 3.5
  • пережимает в ESD
* попутно скачиваются вспомогательные инструменты.
Зачем всё это нужно? Процесс полностью прозрачен. Компоненты ОС (сам ISO и обновления) скачиваются только с серверов Microsoft. Никаких твиков и улучшений.
Прим.:
  • отключать АВ!!! (используется certutil для начального скачивания)
  • Windows Server 2019 Evaluation идёт в 4-х редакциях. Я оставляю две: Windows Server 2019 Standard/Datacenter (Desktop Experience)
  • обновления за май 2021 (SSU+CU)
  • процесс довольно долгий: на i5 4x3GHz 16Gb занимает ~2,5 часа

Windows Server 2019 Standard/Datacenter

>nul 2>&1 dism|| (echo Admin rights required!& exit)
cd /d "%~dp0"
md tmp\mount
set bd=amd64& set bw=x86_64& set bz=-x64
if %PROCESSOR_ARCHITECTURE%==x86 if not defined PROCESSOR_ARCHITEW6432 set bd=x86& set bz=& set bw=i686
msiexec.exe /a https://www.7-zip.org/a/7z1900%bz%.msi /qb TARGETDIR="%CD%\tmp"
for /f "delims=" %%i in ('dir /s/b 7zG.exe') do set p7z="%%~i"
certutil.exe -urlcache -f -split "https://github.com/aria2/aria2/releases/download/release-1.35.0/aria2-1.35.0-win-32bit-build1.zip" tmp\arch.zip
%p7z% x tmp\arch.zip -otmp
for /f "delims=" %%i in ('dir /s/b aria2c.exe') do set aria2c="%%~i"
>tmp\list (
echo https://wimlib.net/downloads/wimlib-1.13.4-windows-%bw%-bin.zip
echo https://rmprepusb.com/wp-content/uploads/2021/03/GetWaikTools-Nov2020-pwd-is-WAIK.zip
echo https://software-download.microsoft.com/download/pr/17763.737.190906-2324.rs5_release_svc_refresh_SERVER_EVAL_x64FRE_ru-ru_1.iso
echo http://download.windowsupdate.com/c/msdownload/update/software/secu/2021/05/windows10.0-kb5003171-x64_30162051d5376b7a19c4c25157347c522e804bbb.msu
echo  dir=tmp\upd\cu
echo http://download.windowsupdate.com/c/msdownload/update/software/secu/2021/05/windows10.0-kb5003243-x64_81350c4efec5a183725fda73091c9ee9d4577bc3.msu
echo  dir=tmp\upd\ssu
)
%aria2c% -itmp\list -x8 -s8 -dtmp --summary-interval=0 --file-allocation=trunc --console-log-level=error
%p7z% x tmp\GetWaikTools-Nov2020-pwd-is-WAIK.zip -otmp -pWAIK
%p7z% x tmp\wimlib-1.13.4-windows-%bw%-bin.zip -otmp\wimlib
%p7z% e tmp\*.iso -ir!*-netfx3-* -otmp\upd\net3
%p7z% e tmp\*.iso -ir!install.wim
tmp\GWT.exe -win10dism -silent
for /f "delims=" %%i in ('dir /s/b %bd%') do set dism="%%~i\dism\dism.exe"
for %%i in (1 2) do tmp\wimlib\wimlib-imagex.exe delete install.wim %%i --soft
for %%i in (
"1,Standard,N69G4-B89J2-4G8F4-WWYCC-J464C"
"2,Datacenter,WMDGN-G9PQG-XVVXX-R3X43-63DFG"
) do for /f "tokens=1-3 delims=," %%a in (%%i) do (
%dism% /Mount-Image /ImageFile:install.wim /Index:%%a /MountDir:tmp\mount
%dism% /Image:tmp\mount /Set-Edition:Server%%b /ProductKey:%%c /AcceptEula
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\net3
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\ssu
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\cu
%dism% /Unmount-Image /MountDir:tmp\mount /Commit
)
tmp\wimlib\wimlib-imagex.exe optimize install.wim --recompress --compress=lzms:100 --solid
ren install.wim install.esd

Windows Server 2022 Standard/Datacenter

>nul 2>&1 dism|| (echo Admin rights required!& exit)
cd /d "%~dp0"
md tmp\mount
set bd=amd64& set bw=x86_64& set bz=-x64
if %PROCESSOR_ARCHITECTURE%==x86 if not defined PROCESSOR_ARCHITEW6432 set bd=x86& set bz=& set bw=i686
msiexec.exe /a https://www.7-zip.org/a/7z1900%bz%.msi /qb TARGETDIR="%CD%\tmp"
for /f "delims=" %%i in ('dir /s/b 7zG.exe') do set p7z="%%~i"
certutil.exe -urlcache -f -split "https://github.com/aria2/aria2/releases/download/release-1.35.0/aria2-1.35.0-win-32bit-build1.zip" tmp\arch.zip
%p7z% x tmp\arch.zip -otmp
for /f "delims=" %%i in ('dir /s/b aria2c.exe') do set aria2c="%%~i"
>tmp\list (
echo https://wimlib.net/downloads/wimlib-1.13.4-windows-%bw%-bin.zip
echo https://rmprepusb.com/wp-content/uploads/2021/03/GetWaikTools-Nov2020-pwd-is-WAIK.zip
echo https://software-download.microsoft.com/download/sg/20348.169.210806-2348.fe_release_svc_refresh_SERVER_EVAL_x64FRE_ru-ru.iso
)
%aria2c% -itmp\list -x8 -s8 -dtmp --summary-interval=0 --file-allocation=trunc --console-log-level=error
%p7z% x tmp\GetWaikTools-Nov2020-pwd-is-WAIK.zip -otmp -pWAIK
%p7z% x tmp\wimlib-1.13.4-windows-%bw%-bin.zip -otmp\wimlib
%p7z% e tmp\*.iso -ir!*-netfx3-* -otmp\upd\net3
%p7z% e tmp\*.iso -ir!install.wim
tmp\GWT.exe -win10dism -silent
for /f "delims=" %%i in ('dir /s/b %bd%') do set dism="%%~i\dism\dism.exe"
for %%i in (1 2) do tmp\wimlib\wimlib-imagex.exe delete install.wim %%i --soft
for %%i in (
"1,Standard,VDYBN-27WPP-V4HQT-9VMD4-VMK7H"
"2,Datacenter,WX4NM-KYWYW-QJJR4-XV3QB-6VM33"
) do for /f "tokens=1-3 delims=," %%a in (%%i) do (
%dism% /Mount-Image /ImageFile:install.wim /Index:%%a /MountDir:tmp\mount
%dism% /Image:tmp\mount /Set-Edition:Server%%b /ProductKey:%%c /AcceptEula
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\net3
%dism% /Unmount-Image /MountDir:tmp\mount /Commit
)
tmp\wimlib\wimlib-imagex.exe optimize install.wim --recompress --compress=lzms:100 --solid
ren install.wim install.esd

Get URL's for latest updates (SSU and CU)

start "" "https://www.catalog.update.microsoft.com/Search.aspx?q=%date:~-4,4%-%date:~3,2% cumulative update windows server 2019 for x64-based"
>nul 2>&1 ping localhost
start "" "https://www.catalog.update.microsoft.com/Search.aspx?q=%date:~-4,4%-%date:~3,2% servicing stack update windows server 2019"
---
Не уверен, что этот концепт будет камрадам интересен. Но на всякий случай.


Последний раз редактировалось: Ander_73 (2021-10-12 14:15), всего редактировалось 6 раз(а)

[Цитировать]

Отправлено: 11-Май-2021 11:40 (спустя 18 часов)

    korsak7
  • 107
  • Стаж: 9 лет
  • Сообщений: 1063
  • Репутация:62

    [+] [-]
Запустил, скачалось - все норм.
Установил винду, потискал установками прог. Капризна зараза.
Показалось что вкл и выкл идет заметно бодрее , чем даже у оптимизированных десяток.
Сложил в склад.

[Цитировать]

Отправлено: 11-Май-2021 12:22 (спустя 41 минута)

    Ander_73
  • 15549
  • Стаж: 7 лет 9 месяцев
  • Сообщений: 3810
  • Репутация:127

    [+] [-]
korsak7, я больше "упирал" на прозрачность процесса. Потому что на трекерах и форумах полно "Серверов", но довольно неясного происхождения. А я как хронический параноик люблю оригиналы ah
---
Ну, и плюс та самая концепция "голой ОС" (я называю это BOSS - bare OS support). То есть берём чистую ОСь, запускаем "голый" батник - и получаем на выходе нечто. Всё, что нам нужно, подкачивается в процессе.

[Цитировать]

Отправлено: 11-Май-2021 14:18 (спустя 1 час 55 минут)

    korsak7
  • 107
  • Стаж: 9 лет
  • Сообщений: 1063
  • Репутация:62

    [+] [-]
Твой батник для чайника - точно такой же темный лес "неясного происхождения" ag
На бабочке есть раздел оригиналов

[Цитировать]

Отправлено: 11-Май-2021 14:38 (спустя 20 минут)

    Ander_73
  • 15549
  • Стаж: 7 лет 9 месяцев
  • Сообщений: 3810
  • Репутация:127

    [+] [-]
85467Твой батник для чайника
Зачем чайнику сервер? Чайнику нужна оптимизированная сборочка.
85467На бабочке есть раздел оригиналов
Я ждал этой мессаги самой первой. Но 3-й тоже нормально.

[Цитировать]

Отправлено: 11-Май-2021 15:21 (спустя 43 минуты)

    loban_ser
  • 17796
  • Стаж: 6 лет 9 месяцев
  • Сообщений: 577
  • Репутация:24

    [+] [-]
Ander_73, aa
Задумка не плохая.

[Цитировать]

Отправлено: 12-Май-2021 10:35 (спустя 19 часов)

    Ander_73
  • 15549
  • Стаж: 7 лет 9 месяцев
  • Сообщений: 3810
  • Репутация:127

    [+] [-]
Поправил в батнике ссылки на новые обновления (май 2021).

[Цитировать]

Отправлено: 14-Май-2021 16:58 (спустя 2 дня 6 часов)

    Ander_73
  • 15549
  • Стаж: 7 лет 9 месяцев
  • Сообщений: 3810
  • Репутация:127

    [+] [-]
Можно сделать сразу обе редакции: Standard и Datacenter.
Для этого после строки:
for /f "delims=" %%i in ('dir /s/b %bd%') do set dism="%%~i\dism\dism.exe"
удалить старый код и вставить такой:
for %%i in (1 2) do tmp\wimlib\wimlib-imagex.exe delete install.wim %%i --soft
for %%i in (
"1,Standard,HM3NG-HXCBR-B3BCG-X9MVG-GMWVQ"
"2,Datacenter,WMDGN-G9PQG-XVVXX-R3X43-63DFG"
) do for /f "tokens=1-3 delims=," %%a in (%%i) do (
%dism% /Mount-Image /ImageFile:install.wim /Index:%%a /MountDir:tmp\mount
%dism% /Image:tmp\mount /Set-Edition:Server%%b /ProductKey:%%c /AcceptEula
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\net3
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\ssu
%dism% /Image:tmp\mount /Add-Package /PackagePath:tmp\upd\cu
%dism% /Unmount-Image /MountDir:tmp\mount /Commit
)
tmp\wimlib\wimlib-imagex.exe optimize install.wim --recompress --compress=lzms:100 --solid
ren install.wim install.esd
Иметь ввиду:
  • время "сборки" практически удваивается
  • при установке редакции называются Evaluation (на самом деле нет)

[Цитировать]

Отправлено: 26-Май-2021 13:04 (спустя 11 дней)

    Ander_73
  • 15549
  • Стаж: 7 лет 9 месяцев
  • Сообщений: 3810
  • Репутация:127

    [+] [-]
Обновление.
  • Перенёс в "шапку" батник для создания сразу обеих редакций Standard/Datacenter
  • Добавил создание Windows Server 2022


Показать сообщения:    

Текущее время: 21-Ноя 16:14

Часовой пояс: UTC + 3


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете голосовать в опросах
Вы не можете прикреплять файлы к сообщениям
Вы можете скачивать файлы