Интеграция обновлений и основы построения сборки Windows 7/8/8.1/10

title Setup Windows (x86/x64)
map --mem (md)+4 (9)
map /_ISO/WinSetup.iso (0xff)
map (hd0) (hd1)
map (hd1) (hd0)
map --rehook
write (9) [FiraDisk]\nStartOptions=cdrom,vmem=find:/_ISO/WinSetup.iso;\n\0
chainloader (0xff)
...где _ISO - имя папки в которой у Вас будет лежать образ
...а WinSetup.iso - имя образа
(имя папки и имя образа заменяете на свои)

Как определить, до каких изданий можно обновить образ
Подключите образ и используйте ключ /Get-TargetEditions
Dism /Image:C:\mount /Get-TargetEditions

Содержимое W7_x86_AiO_New_2.3.cmd

@echo off
REM change wording if needed for echo commands..
SET "Version=v2.3"
TITLE Create Updated Windows 7 AiO ISO %version%
echo.
echo===============================================
echo Check for Admin rights...
echo===============================================
if not "%1"=="am_admin" powershell start -verb runas '%0' am_admin & exit /b
:gotAdmin
pushd "%CD%"
CD /D "%~dp0"
cls
TITLE Create Updated Windows 7 AiO ISO With Install.wim-esd %version%
SETLOCAL ENABLEDELAYEDEXPANSION
SETLOCAL ENABLEEXTENSIONS
SET "Errors="
:: Detect OS Architecture
reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > NUL && ( set "arch=x86" ) || ( set "arch=x64" )
if %arch%==x86 (
set "_wimlib=%~dp0bin\wimlib-imagex.exe"
set "xOS=x86"
) else (
set "_wimlib=%~dp0bin\bin64\wimlib-imagex.exe"
set "xOS=amd64"
)
for /f "tokens=6 delims=[]. " %%# in ('ver') do set winbuild=%%#
set _ADK=0
if %winbuild% gtr 7603 set _ADK=1
set _dism=dism.exe
:check81adk
set regKeyPathFound=1
set wowRegKeyPathFound=1
reg.exe query "HKLM\Software\Wow6432Node\Microsoft\Windows Kits\Installed Roots" /v KitsRoot81 1>nul 2>nul || set wowRegKeyPathFound=0
reg.exe query "HKLM\Software\Microsoft\Windows Kits\Installed Roots" /v KitsRoot81 1>nul 2>nul || set regKeyPathFound=0
if %wowRegKeyPathFound% equ 0 (
if %regKeyPathFound% equ 0 (
goto :check10adk
) else (
set regKeyPath=HKLM\Software\Microsoft\Windows Kits\Installed Roots
)
) else (
set regKeyPath=HKLM\Software\Wow6432Node\Microsoft\Windows Kits\Installed Roots
)
for /f "skip=2 tokens=2*" %%i in ('reg.exe query "%regKeyPath%" /v KitsRoot81') do set "KitsRoot=%%j"
set "DandIRoot=%KitsRoot%Assessment and Deployment Kit\Deployment Tools"
if exist "%DandIRoot%\%xOS%\DISM\dism.exe" (
set _ADK=1
set _dism="%DandIRoot%\%xOS%\DISM\dism.exe"
)
goto :START
:check10adk
set regKeyPathFound=1
set wowRegKeyPathFound=1
reg.exe query "HKLM\Software\Wow6432Node\Microsoft\Windows Kits\Installed Roots" /v KitsRoot10 1>nul 2>nul || set wowRegKeyPathFound=0
reg.exe query "HKLM\Software\Microsoft\Windows Kits\Installed Roots" /v KitsRoot10 1>nul 2>nul || set regKeyPathFound=0
if %wowRegKeyPathFound% equ 0 (
if %regKeyPathFound% equ 0 (
goto :START
) else (
set regKeyPath=HKLM\Software\Microsoft\Windows Kits\Installed Roots
)
) else (
set regKeyPath=HKLM\Software\Wow6432Node\Microsoft\Windows Kits\Installed Roots
)
for /f "skip=2 tokens=2*" %%i in ('reg.exe query "%regKeyPath%" /v KitsRoot10') do set "KitsRoot=%%j"
set "DandIRoot=%KitsRoot%Assessment and Deployment Kit\Deployment Tools"
if exist "%DandIRoot%\%xOS%\DISM\dism.exe" (
set _ADK=1
set _dism="%DandIRoot%\%xOS%\DISM\dism.exe"
)
goto :START
:START
IF %_ADK% EQU 1 GOTO :Prepare
echo.
echo===============================================
echo Warning:
echo===============================================
echo.
echo Windows 7 built-in Dism.exe tool might not properly handle all operations.
echo.
echo It is recommended to install Windows ADK 8.1
echo or Windows ADK 10 (non-Insider Preview).
echo.
ECHO==========================================================
ECHO.
ECHO [ 1 ] - Continue without Windows ADK ^(at your own risk^)
ECHO.
ECHO [ 2 ] - Exit
ECHO.
ECHO==========================================================
ECHO.
SET "CHOICE="
SET /P CHOICE="* Type your option and press Enter: "
IF /I '%CHOICE%'=='1' GOTO :Prepare
IF /I '%CHOICE%'=='2' EXIT
IF NOT DEFINED CHOICE GOTO :START
:Prepare
echo.
echo Preparing...
echo.
%_dism% /Cleanup-Wim
if exist "TEMP" rmdir /q /s "TEMP"
if exist "ISO" rmdir /q /s "ISO"
if exist "WIM" rmdir /q /s "WIM"
if exist "WinRE_x86" rmdir /q /s "WinRE_x86"
if exist "WIN7ISO" rmdir /q /s "WIN7ISO"
if exist "WIN7ENTISO" rmdir /q /s "WIN7ENTISO"
if exist "WIN10ISO" rmdir /q /s "WIN10ISO"
if exist "Dart_w7\Dart_w7" RD /S /Q "Dart_w7\Dart_w7"
if exist "Dart_w7\Dart_w7_LP" RD /S /Q "Dart_w7\Dart_w7_LP"
if exist "%SystemDrive%\WinRE_Mount" RD /S /Q "%SystemDrive%\WinRE_Mount"
if exist "EXE\*.WA" del "EXE\*.WA"
if exist "EXE\SmartFix*.exe" del /f /q "EXE\SmartFix*.exe"
if exist "temp1" RD /S /Q "temp1"
if exist "%SystemDrive%\AiO_Mount" rmdir /q /s "%SystemDrive%\AiO_Mount"
echo.
echo Creating Work folders...
mkdir "ISO" 2>&1
mkdir "WIM" 2>&1
mkdir "WinRE_x86" 2>&1
mkdir "WIN7ISO" 2>&1
mkdir "WIN7ENTISO" 2>&1
mkdir "WIN10ISO" 2>&1
mkdir "temp1" >NUL 2>&1
mkdir "%SystemDrive%\AiO_Mount" 2>&1
mkdir "%SystemDrive%\WinRE_Mount" 2>&1
CLS
echo.
echo===============================================
echo Settings
echo===============================================
:AskDartYesNO
REM DaRT Settings
SET "DART="
echo.
ECHO==========================================================
ECHO Integrate DaRT ^?
ECHO==========================================================
ECHO.
ECHO [ 1 ] - Integrate DaRT
ECHO.
ECHO [ 2 ] - Don't Integrate DaRT
ECHO.
ECHO==========================================================
ECHO.
SET "CHOICE="
SET /P CHOICE="* Type your option and press Enter: "
IF /I '%CHOICE%'=='1' SET "DART=DaRT1"
IF /I '%CHOICE%'=='2' SET "DART=DaRT0"
IF NOT DEFINED DART GOTO :AskDartYesNO
:AskSMFIXYesNo
REM SMFIX Settings
SET "SMFIX="
echo.
ECHO==========================================================
ECHO Integrate SmartFix ^?
ECHO==========================================================
ECHO.
ECHO [ 1 ] - Integrate SmartFix
ECHO.
ECHO [ 2 ] - Don't Integrate SmartFix
ECHO.
ECHO==========================================================
ECHO.
SET "CHOICE="
SET /P CHOICE="* Type your option and press Enter: "
IF /I '%CHOICE%'=='1' SET "SMFIX=SMFIX1"
IF /I '%CHOICE%'=='2' SET "SMFIX=SMFIX0"
IF NOT DEFINED SMFIX GOTO :AskSMFIXYesNO
:AskDRVIWMesNo
REM DRVIWM Settings
SET "DRVIWM="
echo.
ECHO==========================================================
ECHO Integrate Drivers Into Install.wim ^?
ECHO==========================================================
ECHO.
ECHO [ 1 ] - Integrate Drivers Into Install.wim ^?
ECHO.
ECHO [ 2 ] - Don't Integrate Into Install.wim ^?
ECHO.
ECHO==========================================================
ECHO.
SET "CHOICE="
SET /P CHOICE="* Type your option and press Enter: "
IF /I '%CHOICE%'=='1' SET "DRVIWM=DRVIWM1"
IF /I '%CHOICE%'=='2' SET "DRVIWM=DRVIWM0"
IF NOT DEFINED DRVIWM GOTO :AskDRVIWMesNo
:AskDRVWREYesNo
REM DRVWRE Settings
SET "DRVWRE="
echo.
ECHO==========================================================
ECHO Integrate Drivers Into WinRE ^?
ECHO==========================================================
ECHO.
ECHO [ 1 ] - Integrate Drivers Into WinRE ^?
ECHO.
ECHO [ 2 ] - Don't Integrate Into WinRE ^?
ECHO.
ECHO==========================================================
ECHO.
SET "CHOICE="
SET /P CHOICE="* Type your option and press Enter: "
IF /I '%CHOICE%'=='1' SET "DRVWRE=DRVWRE1"
IF /I '%CHOICE%'=='2' SET "DRVWRE=DRVWRE0"
IF NOT DEFINED DRVWRE GOTO :AskDRVWREYesNo
:Compression
REM ========= ESD/WIM Selection =========
SET "ESDWIM="
echo.
ECHO===========================================================
ECHO Select the compression type for the "Install" file
ECHO===========================================================
ECHO.
ECHO [ 1 ] - ESD File - Smaller install file, longer creation.
ECHO.
ECHO [ 2 ] - WIM File - Standard install file.
ECHO.
ECHO===========================================================
ECHO.
SET "CHOICE="
SET /P CHOICE="* Type your option and press Enter: "
IF /I '%CHOICE%'=='1' SET "ESDWIM=ESD"
IF /I '%CHOICE%'=='2' SET "ESDWIM=WIM"
IF NOT DEFINED ESDWIM GOTO :Compression
echo===============================================
echo Script Started At %time%
echo===============================================
echo.
echo===============================================
echo Extracting Source ISO's...
echo===============================================
bin\7z x -y -o"WIN7ISO\" "Source_ISOs\7_x86\"
echo.
bin\7z x -y -o"WIN10ISO\" "Source_ISOs\10_x86\"
REM detect extracted win7 iso language
set "IsoLang=ar-SA,bg-BG,cs-CZ,da-DK,de-DE,el-GR,en-US,es-ES,et-EE,fi-FI,fr-FR,he-IL,hr-HR,hu-HU,it-IT,ja-JP,ko-KR,lt-LT,lv-LV,nb-NO,nl-NL,pl-PL,pt-BR,pt-PT,ro-RO,ru-RU,sk-SK,sl-SI,sr-Latn-CS,sv-SE,th-TH,tr-TR,uk-UA,zh-CN,zh-HK,zh-TW"
for %%i in (%IsoLang%) do if exist "WIN7ISO\sources\%%i\*.mui" set %%i=1
REM set starter xml lang
for %%i in (%IsoLang%) do if defined %%i (
SET "StarterLang=%%i"
)
echo.
echo================================================
echo Copying Content Of Addons_x86 To EXE Folder...
echo================================================
copy /Y "Addons_x86\*vcredist*.WA" "EXE" >NUL 2>&1
copy /Y "Addons_x86\*DirectX*.WA" "EXE" >NUL 2>&1
copy /Y "Addons_x86\*dotNetFx48_*.WA" "EXE" >NUL 2>&1
for %%# in (
ar-SA:ARA cs-CZ:CSY da-DK:DAN de-DE:DEU
el-GR:ELL es-ES:ESN fi-FI:FIN fr-FR:FRA
he-IL:HEB hr-HR:HUN it-IT:ITA ja-JP:JPN
ko-KR:KOR nl-NL:NLD nb-NO:NOR pl-PL:PLK
pt-BR:PTB pt-PT:PTG ru-RU:RUS sv-SE:SVE
tr-TR:TRK zh-CN:CHS zh-HK:CHT zh-TW:CHT
) do for /f "tokens=1,2 delims=:" %%A in ("%%#") do (
if /I "%StarterLang%"=="%%A" copy /Y "Addons_x86\*dotNetFx48LP_*%%B*.WA" "EXE" >NUL 2>&1
)
REM skip Dart lang check if OFF
IF /I "%DART%"=="DaRT0" GOTO :Compression2
REM set LANG to the only languages that are available for dart as i think only a few are available..
SET "DartLang=en-us"
set "lang=de-de, en-us, es-es, fr-fr, it-it, ja-jp, ko-kr, pt-br, ru-ru, zh-cn, zh-tw"
REM loop to check detected lang against Dart supported langs, then set dartlang var to it else use default en-us.
for %%i in (%IsoLang%) do if defined %%i (
for %%a in (%lang%) do if /I "%%i"=="%%a" SET "DartLang=%%a"
)
if not exist "Dart_w7\Dart_w7_%DartLang%.tpk" (
echo.
echo DaRT language %DartLang% does not exist within the DaRT folder
echo using en-US as default.
SET "DartLang=en-US"
Timeout /T 2 >nul
)
IF DEFINED DartLang (
echo.
echo===========================================================
echo DaRT Language Used : %DartLang%
echo===========================================================
)
timeout /T 1 /nobreak >nul
:Compression2
echo.
echo===============================================
echo Copying required ISO Files...
echo===============================================
copy /Y "WIN10ISO\bootmgr" "ISO" >NUL 2>&1
copy /Y "WIN10ISO\bootmgr.efi" "ISO" >NUL 2>&1
echo.
for /D %%i in (WIN10ISO\*) do (
if /I "[%%~nxi]" == "[sources]" set "nocopy=1"
if /I "[%%~nxi]" == "[support]" set "nocopy=1"
if /I "[%%~nxi]" == "[upgrade]" set "nocopy=1"
if !nocopy! EQU 0 xcopy /cherkyq %%i "ISO\%%~nxi\" >NUL 2>&1
set "nocopy=0"
) >NUL 2>&1
echo.
echo===============================================
echo Create ISO\Sources...
echo===============================================
mkdir "ISO\sources"
echo.
echo Copy over files...
copy /Y "WIN10ISO\Sources\setup.exe" "ISO\Sources" >NUL 2>&1
copy /Y "WIN10ISO\Sources\lang.ini" "ISO\Sources" >NUL 2>&1
copy /Y "WIN10ISO\Sources\boot.wim" "ISO\Sources" >NUL 2>&1
copy /Y "EI\ei.cfg" "ISO\Sources\ei.cfg" >NUL 2>&1
xcopy /s /i /Q "OEM" "ISO\Sources" >NUL 2>&1
echo.
echo===============================================
echo Modifying Win 10 boot.wim to look like 7...
echo===============================================
%_wimlib% extract "WIN7ISO\sources\boot.wim" 2 "sources\background.bmp" --no-acls --dest-dir=TEMP
%_wimlib% extract "WIN7ISO\sources\boot.wim" 2 "sources\arunimg.dll" --no-acls --dest-dir=TEMP
%_wimlib% extract "WIN7ISO\sources\boot.wim" 2 "sources\spwizimg.dll" --no-acls --dest-dir=TEMP
%_wimlib% update "ISO\Sources\boot.wim" 2 --command="add 'TEMP\' '\sources'"
echo.
echo===============================================
echo Optimizing Boot.wim...
echo===============================================
%_wimlib% optimize "ISO\sources\boot.wim"
:Starter
echo.
echo===============================================
echo. Working On Starter %StarterLang%...
echo===============================================
bin\imagex /Export "WIN7ISO\Sources\install.wim" 1 "WIM\aio.install.wim" /Compress maximum
%_dism% /Get-WimInfo /WimFile:WIM\aio.install.wim
%_wimlib% info "WIM\aio.install.wim" 1 "Windows 7 Starter" "Windows 7 Starter" --image-property DISPLAYNAME="Windows 7 Starter" --image-property DISPLAYDESCRIPTION="Windows 7 Starter"
%_dism% /Get-WimInfo /WimFile:WIM\aio.install.wim
:WINRE
IF /I "%DART%"=="DaRT0" IF /I "%DRVWRE%"=="DRVWRE0" GOTO :TEST2
:EXTRACT
%_wimlib% extract "WIM\aio.install.wim" 1 "\Windows\System32\Recovery\winre.wim" --no-acls --dest-dir=Winre_x86
:TEST
IF /I "%DRVWRE%"=="DRVWRE1" GOTO :WINREDRV
IF /I "%DRVWRE%"=="DRVWRE0" GOTO :RESUME1
:WINREDRV
echo.
echo===============================================
echo WinRE - Driver Integration...
echo===============================================
rem %_wimlib% extract "WIM\aio.install.wim" 1 "\Windows\System32\Recovery\winre.wim" --no-acls --dest-dir=Winre_x86
echo.
echo===============================================
echo Mounting Winre...
echo===============================================
%_dism% /mount-wim /wimfile:"Winre_x86\winre.wim" /index:1 /mountdir:"%SystemDrive%\WinRE_Mount"
echo.
echo.
echo===============================================
echo WinRE - Integrating '(W)LAN' Drivers...
echo===============================================
%_dism% /image:"%SystemDrive%\WinRE_Mount" /Add-Driver /driver:"Drivers\(W)LAN_7_x86" /recurse
echo.
echo.
echo===============================================
echo WinRE - Integrating 'nVME' Drivers...
echo===============================================
%_dism% /image:"%SystemDrive%\WinRE_Mount" /Add-Driver /driver:"Drivers\nVME_7_x86" /recurse
echo.
%_dism% /Unmount-Wim /MountDir:"%SystemDrive%\WinRE_Mount" /Commit
:RESUME1
IF /I "%DART%"=="DaRT1" GOTO :DaRT
IF /I "%DART%"=="DaRT0" GOTO :OPTIMIZE
GOTO :WIM
echo.
:DaRT
echo.
echo===============================================
echo Extracting %DartLang% DaRT packages...
echo===============================================
bin\7z x -y -o"Dart_w7\Dart_w7" "Dart_w7\Dart_w7.tpk"
bin\7z x -y -o"Dart_w7\Dart_w7_LP" "Dart_w7\Dart_w7_%DartLang%.tpk"
echo.
echo===============================================
echo WinRE - DaRT 7 Integration...
echo===============================================
%_wimlib% update "Winre_x86\Winre.wim" 1 --command="add 'Dart_w7\Dart_w7\1\' '\'"
%_wimlib% update "Winre_x86\Winre.wim" 1 --command="add 'Dart_w7\Dart_w7_LP\1\' '\'"
:OPTIMIZE
echo.
echo Optimizing WinRe...
%_wimlib% optimize "Winre_x86\Winre.wim" --check --recompress
%_wimlib% update "WIM\aio.install.wim" 1 --command="add 'Winre_x86\Winre.wim' '\Windows\System32\Recovery\winre.wim'"
del /f /q "Winre_x86\winre.wim" >NUL 2>&1
:TEST2
IF /I "%DRVIWM%"=="DRVIWM1" GOTO :Install_wim
IF /I "%DRVIWM%"=="DRVIWM0" GOTO :RESUME2
:Install_wim
echo.
echo=====================================================================
echo Integrating Drivers into Install.wim...
echo=====================================================================
%_dism% /mount-wim /wimfile:WIM\aio.install.wim /index:1 /mountdir:"%SystemDrive%\AiO_Mount"
%_dism% /image:"%SystemDrive%\AiO_Mount" /Add-Driver /driver:"Drivers\(W)LAN_7_x86" /recurse
%_dism% /image:"%SystemDrive%\AiO_Mount" /Add-Driver /driver:"Drivers\nVME_7_x86" /recurse
%_dism% /Unmount-Wim /MountDir:"%SystemDrive%\AiO_Mount" /Commit
IF /I "%SMFIX%"=="SMFIX1" GOTO :SMFIX
IF /I "%SMFIX%"=="SMFIX0" GOTO :SiMPLiX
:RESUME2
IF /I "%SMFIX%"=="SMFIX1" GOTO :SMFIX
IF /I "%SMFIX%"=="SMFIX0" GOTO :SiMPLiX
:SMFIX
copy /Y "SMARTFIX\SmartFix*.exe" "EXE" >NUL 2>&1
:SiMPLiX
echo.
echo==============================================
echo Starting SiMPLiX UpdatePack...
echo==============================================
call SiMPLiX.bat
TITLE Create Updated Windows 7 AiO ISO With Install.wim-esd %version%
echo==============================================
echo Resuming AiO Script...
echo==============================================
echo.
echo==============================================
echo Creating All SKU's And Setting Edition Flags...
echo==============================================
echo.
echo==============================================
echo Creating HomeBasic %StarterLang%...
echo==============================================
echo.
bin\imagex /mountrw wim\aio.install.wim 1 "%SystemDrive%\AiO_Mount"
%_dism% /Image:"%SystemDrive%\AiO_Mount" /Set-Edition:HomeBasic
bin\imagex /commit /append "%SystemDrive%\AiO_Mount" Windows 7 HomeBasic
bin\imagex /unmount "%SystemDrive%\AiO_Mount"
Bin\imagex.exe /flags "HomeBasic" /info "WIM\aio.install.wim" 2 "Windows 7 HomeBasic" "Windows 7 HomeBasic"
echo==============================================
echo Creating HomePremium %StarterLang%...
echo==============================================
bin\imagex /mountrw wim\aio.install.wim 1 "%SystemDrive%\AiO_Mount"
%_dism% /Image:"%SystemDrive%\AiO_Mount" /Set-Edition:HomePremium
bin\imagex /commit /append "%SystemDrive%\AiO_Mount" Windows 7 HomePremium
bin\imagex /unmount "%SystemDrive%\AiO_Mount"
Bin\imagex.exe /flags "HomePremium" /info "WIM\aio.install.wim" 3 "Windows 7 HomePremium" "Windows 7 HomePremium"
echo==============================================
echo Creating Professional %StarterLang%...
echo==============================================
bin\imagex /mountrw wim\aio.install.wim 1 "%SystemDrive%\AiO_Mount"
%_dism% /Image:"%SystemDrive%\AiO_Mount" /Set-Edition:Professional
bin\imagex /commit /append "%SystemDrive%\AiO_Mount" Windows 7 Professional
bin\imagex /unmount "%SystemDrive%\AiO_Mount"
Bin\imagex.exe /flags "Professional" /info "WIM\aio.install.wim" 4 "Windows 7 Professional" "Windows 7 Professional"
echo==============================================
echo Creating Ultimate %StarterLang%...
echo==============================================
bin\imagex /mountrw wim\aio.install.wim 1 "%SystemDrive%\AiO_Mount"
%_dism% /Image:"%SystemDrive%\AiO_Mount" /Set-Edition:Ultimate
bin\imagex /commit /append "%SystemDrive%\AiO_Mount" Windows 7 Ultimate
bin\imagex /unmount "%SystemDrive%\AiO_Mount"
Bin\imagex.exe /flags "Ultimate" /info "WIM\aio.install.wim" 5 "Windows 7 Ultimate" "Windows 7 Ultimate"
echo==============================================
echo Creating Enterprise %StarterLang%...
echo==============================================
bin\imagex /mountrw wim\aio.install.wim 1 "%SystemDrive%\AiO_Mount"
%_dism% /scratchdir:"%~dp0temp1" /image:%SystemDrive%\AiO_Mount /apply-unattend:XML\x86\1.xml
echo.
echo===============================================
echo. Inserting %StarterLang% language xml...
echo===============================================
%_dism% /scratchdir:"%~dp0temp1" /image:%SystemDrive%\AiO_Mount /apply-unattend:XML\x86\%StarterLang%.xml
%_dism% /Image:"%SystemDrive%\AiO_Mount" /Set-Edition:Enterprise
%_dism% /Image:"%SystemDrive%\AiO_Mount" /set-productkey:33PXH-7Y6KF-2VJC9-XBBR8-HVTHH
bin\imagex /commit /append "%SystemDrive%\AiO_Mount" Windows 7 Enterprise
bin\imagex /unmount "%SystemDrive%\AiO_Mount"
Bin\imagex.exe /flags "Enterprise" /info "WIM\aio.install.wim" 6 "Windows 7 Enterprise" "Windows 7 Enterprise"
%_wimlib% optimize "WIM\aio.install.wim"
echo.
echo==============================================
echo Setting last modification date...
echo==============================================
for /f "tokens=3 delims=: " %%i in ('%_wimlib% info WIM\aio.install.wim ^| findstr /c:"Image Count" 2^>nul') do set "images=%%i"
for /L %%i in (1,1,%images%) do (
for /f "tokens=3 delims=<>" %%a in ('Bin\imagex /info WIM\aio.install.wim %%i ^| find /i "<HIGHPART>" 2^>nul') do set "HIGHPART=%%a"
for /f "tokens=3 delims=<>" %%a in ('Bin\imagex /info WIM\aio.install.wim %%i ^| find /i "<LOWPART>" 2^>nul') do set "LOWPART=%%a"
%_wimlib% info WIM\aio.install.wim %%i --image-property CREATIONTIME/HIGHPART=!HIGHPART! --image-property CREATIONTIME/LOWPART=!LOWPART! >nul
)
timeout /t 1 /Nobreak >nul
echo.
echo===============================================
echo Content of WIM...
echo===============================================
%_dism% /Get-WimInfo /WimFile:WIM\aio.install.wim
IF /I "%ESDWIM%"=="ESD" GOTO :ESD
IF /I "%ESDWIM%"=="WIM" GOTO :WIM
GOTO :WIM
:ESD
echo %time%
echo.
echo===============================================
echo Creating Install.ESD. Please Wait...
echo===============================================
%_wimlib% export "WIM\aio.install.wim" all "ISO\Sources\install.esd" --compress=LZMS --solid
timeout /t 2 >nul
echo %time%
goto :Donewimesd
:WIM
echo %time%
echo.
echo===============================================
echo Creating Install.WIM. Please Wait...
echo===============================================
%_wimlib% export "WIM\aio.install.wim" all "ISO\Sources\install.wim" --compress=LZX
timeout /t 2 >nul
echo %time%
echo.
echo.
:Donewimesd
timeout /T 2 /nobreak >nul
echo.
echo===============================================
echo Creating ISO...
echo===============================================
for /f "tokens=2 delims==." %%# in ('wmic os get localdatetime /value') do set "_date=%%#"
set "isodate=%_date:~0,4%-%_date:~4,2%-%_date:~6,2%"
bin\cdimage.exe -bootdata:2#p0,e,b"ISO\boot\etfsboot.com"#pEF,e,b"ISO\efi\Microsoft\boot\efisys.bin" -o -m -u2 -udfver102 -lWin_7_AiO_x86_%StarterLang% ISO Win_7_AiO_x86_%StarterLang%_%isodate%.iso
echo %time%
echo.
echo===============================================
echo All Processing Complete...
echo===============================================
echo.
echo===============================================
echo Cleanup...
echo===============================================
%_dism% /Cleanup-Wim
if exist "TEMP" rmdir /q /s "TEMP"
if exist "ISO" rmdir /q /s "ISO"
if exist "WIM" rmdir /q /s "WIM"
if exist "WinRE_x86" rmdir /q /s "WinRE_x86"
if exist "WIN7ISO" rmdir /q /s "WIN7ISO"
if exist "WIN7ENTISO" rmdir /q /s "WIN7ENTISO"
if exist "WIN10ISO" rmdir /q /s "WIN10ISO"
if exist "Dart_w7\Dart_w7" RD /S /Q "Dart_w7\Dart_w7"
if exist "Dart_w7\Dart_w7_LP" RD /S /Q "Dart_w7\Dart_w7_LP"
if exist "temp1" RD /S /Q "temp1"
if exist "%SystemDrive%\AiO_Mount" rmdir /q /s "%SystemDrive%\AiO_Mount"
if exist "%SystemDrive%\WinRE_Mount" rmdir /q /s "%SystemDrive%\WinRE_Mount"
echo==============================================
echo Cleaning Up Addons_x86 From EXE Folder...
echo==============================================
if exist "EXE\*.WA" del /f /q "EXE\*.WA"
if exist "EXE\SmartFix*.exe" del /f /q "EXE\SmartFix*.exe"
:Errors
IF DEFINED Error echo. & echo Errors detected, unable to continue.
echo.
echo.
echo===============================================
echo. Script Finished At %time%
echo===============================================
echo.
echo Press any key to exit...
pause >nul

Я.Д

https://disk.yandex.ua/d/AI9OtaiiY0jhwA
PW = SiMPLiX