Батники - вопросы и решения

netsh wlan delete profile "SSID"
netsh wlan add profile filename="WIFI.xml"
netsh wlan connect name="WIFI"

@Echo OFF
:: Replace "?" in your SSID and SharedKey and You are Ready to Go!
set "SSID=?"
set "SharedKey=?"
set "xml_name=wifi.xml"
   Call :XML "%SSID%" "%SharedKey%" "%xml_name%"
   netsh wlan add profile filename=%xml_name%
   Del /F /Q "%xml_name%" >nul
   Goto :eof
:XML [XML setting File form]
:: Take 4 inputs: Name, SSID, SharedKey & output xml file name.
set "SSID=%~1"
set "SharedKey=%~2"
set "output=%~3"
(
echo ^<?xml version="1.0"?^>
echo ^<WLANProfile xmlns="http://www.microsoft.com/networking/WLAN/profile/v1"^>
echo ^<name^>%SSID%^</name^>
echo ^<SSIDConfig^>
echo ^<SSID^>
echo ^<name^>%SSID%^</name^>
echo ^</SSID^>
echo ^<nonBroadcast^>true^</nonBroadcast^>
echo ^</SSIDConfig^>
echo ^<connectionType^>ESS^</connectionType^>
echo ^<connectionMode^>auto^</connectionMode^>
echo ^<MSM^>
echo ^<security^>
echo ^<authEncryption^>
echo ^<authentication^>WPA2PSK^</authentication^>
echo ^<encryption^>AES^</encryption^>
echo ^<useOneX^>false^</useOneX^>
echo ^</authEncryption^>
echo ^<sharedKey^>
echo ^<keyType^>passPhrase^</keyType^>
echo ^<protected^>false^</protected^>
echo ^<keyMaterial^>%SharedKey%^</keyMaterial^>
echo ^</sharedKey^>
echo ^</security^>
echo ^</MSM^>
echo ^</WLANProfile^>
)>"%output%"
Goto :EOF