Call_Server v.2 - утилита автоподключения к сети и шаром

Код:

@echo off
cd /d "%~dp0"
Title Connecting to Server by dimo70
MODE CON: COLS=55 LINES=12
Color 0E
echo.
:: Set Your Wi-Fi settings
set "SSID=Iztok"
set "SharedKey=02721847"
set "xml_name=wifi.xml"
:: Set other settings
set "serv=W"
set "shared=D"
set "pass=1"
set "usr=1"
:pingtest
echo Checking connection! Please wait...
echo.
Ping -n 2 Google.com | find "TTL"
IF ERRORLEVEL 1 goto option-2
:Option-1
echo.
echo Opening Shared Resources ...
cmdkey /add:%serv% /user:%computername%\%usr% /pass:%pass%
start \\%serv%\%shared% & exit
if not exist \\%serv%\%shared% goto :pingtest
:Option-2
echo Connecting to Wi-Fi! Please wait...
echo.
Call :XML "%SSID%" "%SharedKey%" "%xml_name%"
netsh wlan add profile filename=%xml_name%
Del /F /Q "%xml_name%" >nul
timeout /t 4 >nul
Goto :pingtest
:XML [XML setting File form]
set "SSID=%~1"
set "SharedKey=%~2"
set "output=%~3"
(
echo ^<?xml version="1.0"?^>
echo ^<WLANProfile xmlns="http://www.microsoft.com/networking/WLAN/profile/v1"^>
echo ^<name^>%SSID%^</name^>
echo ^<SSIDConfig^>
echo ^<SSID^>
echo ^<name^>%SSID%^</name^>
echo ^</SSID^>
echo ^<nonBroadcast^>true^</nonBroadcast^>
echo ^</SSIDConfig^>
echo ^<connectionType^>ESS^</connectionType^>
echo ^<connectionMode^>auto^</connectionMode^>
echo ^<MSM^>
echo ^<security^>
echo ^<authEncryption^>
echo ^<authentication^>WPA2PSK^</authentication^>
echo ^<encryption^>AES^</encryption^>
echo ^<useOneX^>false^</useOneX^>
echo ^</authEncryption^>
echo ^<sharedKey^>
echo ^<keyType^>passPhrase^</keyType^>
echo ^<protected^>false^</protected^>
echo ^<keyMaterial^>%SharedKey%^</keyMaterial^>
echo ^</sharedKey^>
echo ^</security^>
echo ^</MSM^>
echo ^</WLANProfile^>
)>"%output%"
Goto :EOF
:exit
exit

код

@echo off
mode con cols=60 lines=12
color 2E
Title Connecting to Server ...
echo Connecting to Wi-Fi Router...
start /w AutoWiFi.cmd
timeout /t 1
echo.
echo Connecting to Server. Please wait ...
echo.
echo Wake on LAN. Please wait ...
wolcmd 1C1B0D953E4B 192.168.2.2 255.255.255.0 9
echo Opening Shared Resources ...
net use \\W\D 1 /user:1 /p:yes
start /w explorer "\\W\D\"
net use \\W\E 1 /user:1 /p:yes
start /w explorer "\\W\E\"
start /w \\W\D\TTL.exe
exit