Мини инстал.

envi i=0
//Добавляем пункты в меню, название, тип запуска, путь, время выполнения (для прогресса)
ArrayAdd "Proga1" "-wait" "%CurDir%\prog\Proga1.cmd" 10
ArrayAdd "Proga2" "-wait" "%CurDir%\prog\Proga1.cmd" 50
ArrayAdd "Proga3" "-wait" "%CurDir%\prog\Proga1.cmd" 20
ArrayAdd "Proga4" "-wait" "%CurDir%\prog\Proga1.cmd" 70
ArrayAdd "Proga5" "-wait" "%CurDir%\prog\Proga1.cmd" 20
//%n% - к-во пунктов меню
calc n=%i% - 1
//Вычисляем размер окна
calc w=400
calc h=int(%n%/2)*20 + 170
//Создаем основное окно
@Windows %w% %h%
exit
_sub Windows,w%1h%2,Установка программ,, // Размер основного окна и его название.
  labe Label1,l10t10w%1h20,Выберите программы для установки ,,0xaaaaaa,16 // Местоположение надписи, цвет,размер шрифта.
   //Инфо
  calc l=15
  calc t=int(%n%/2)*20 + 64
  labe Label2,l%l%t%t%w%1h20,======  Привет ======
  //Создаем в цикле Чек боксы
  envi i=0
  loop %i%<=%n%,
  {
    calc l=mod(%i%,2)*205 + 15
    calc t=int(%i%/2)*20 + 40
    chek Chk[%i%],l%l%t%t%w150h20,%Name[%i%]%,,1 // Чек бокс и его местоположение в окне + Имя программы
    calc i=%i% + 1
  }
  //Кнопки
  calc l=15
  calc t=int(%n%/2)*20 + 108
  item Button1,l%l%t%t%w100h24,Выбрать все,Sel 1 // местоположение кнопки "выбрать все"
  calc l=120
  item Button2,l%l%t%t%w100h24,Снять выбор,Sel 0 // местоположение кнопки "снять выбор"
  calc l=280
  item Button3,l%l%t%t%w100h24,Установить,Install // местоположение кнопки "Установить"
  calc l=15
  calc t=int(%n%/2)*20 + 84
  pbar Pbar,l%l%t%t%w365h20,, // Прогрес бар и его место положение в окне
_end
_sub ArrayAdd
  envi Name[%i%]=%~1
  envi StartType[%i%]=%~2
  envi InstString[%i%]=%~3
  envi InstTime[%i%]=%~4
  calc i=%i% + 1
_end
_sub Sel
  envi i=0
  loop %i%<=%n%,
  {
    envi @Chk[%i%].Check=%1
    calc i=%i% + 1
  }
_end
_sub CheckSel
  //Вычисляем общее время выполнения выбранных пунктов
  envi SummaryTime=0
  envi i=0
  loop %i%<=%n%,
  {
    ifex $%Chk[%i%].Check%=1,calc SummaryTime=%SummaryTime% + %InstTime[%i%]%
    calc i=%i% + 1
  }
_end
_sub Install
  mess Установить выбранные приложения?@#YN
  find $%YESNO%=YES,
  {
    envi @Pbar=0
    CheckSel
    envi CurrentTime=0
    envi i=0
    loop %i%<=%n%,
    {
      ifex $%Chk[%i%].Check%=1,
        {
          envi @Label2=*** Установка  %Name[%i%]% ***
          exec %StartType[%i%]% %InstString[%i%]%
          calc CurrentTime=%CurrentTime% + %InstTime[%i%]%
          calc Percent=%CurrentTime%/%SummaryTime%*100
          envi @Pbar=%Percent%
          envi @Chk[%i%].Check=0
        }
      calc i=%i% + 1
    }
    envi @Label2=*** Все задания выполнены !!! ***
  }
_end