Редакторы для PECMD

#HH_DISPLAY_TOPIC = 1
#HH_KEYWORD_LOOKUP = $0D
#HH_SYNC = $09
#HH_DISPLAY_INDEX = $02
#PB_Shortcut_SrodFlag=1<<16
Structure tAKLIN
  cbStruct.l
  fReserved.l
  pszKeywords.s
  pszUrl.s
  pszMsgText.s
  pszMsgTitle.s
  pszWindow.s
  fIndexOnFail.l
EndStructure
Global hWnd, hWnd_Find, g_ID_Search, ID , g_class.s, classText.s = Space(256)
Procedure.l enumChildren(hwnd.l)
  If hwnd
    GetClassName_(hwnd, @classText, 256)
    If classText = g_class
      ID = ID + 1
      If ID = g_ID_Search
        hWnd_Find = hwnd
        ProcedureReturn 0
      EndIf
    EndIf
    ProcedureReturn 1
  EndIf
  ProcedureReturn 0
EndProcedure
Procedure _KillProcess(Pid)
  Protected phandle = OpenProcess_(#PROCESS_TERMINATE, #False, Pid)
  If phandle <> #Null
    If TerminateProcess_(phandle, 1)
      result = #True
    EndIf
    CloseHandle_(phandle)
  EndIf
  ProcedureReturn result
EndProcedure
Procedure _KillOtherProcess(ProcName$, CurrentPid.l)
  Protected ProcNameTmp$=Space(#MAX_PATH),ProcessFound,Pid,Process.ProcessENTRY32,hProcess
  Process.ProcessENTRY32\dwSize = SizeOf(ProcessENTRY32)
  Protected psapi_dll=OpenLibrary(#PB_Any,"psapi.dll")
  Protected Snapshot = CreateToolhelp32Snapshot_(#TH32CS_SNAPPROCESS, 0)
  If Snapshot
    ProcessFound = Process32First_(Snapshot, @Process)
    While ProcessFound
      Pid  = Process\th32ProcessID
      If Pid <> CurrentPid
        hProcess=OpenProcess_(#PROCESS_QUERY_INFORMATION|#PROCESS_VM_READ,#Null,Pid)
        If hProcess
          CallFunction(psapi_dll,"GetModuleFileNameExW",hProcess,#Null,@ProcNameTmp$,#MAX_PATH)
          CloseHandle_(hProcess)
          If LCase(ProcName$)=LCase(ProcNameTmp$)
            _KillProcess(Pid)
          EndIf
        EndIf
      EndIf
      ProcessFound = Process32Next_(Snapshot, @Process)
    Wend
  EndIf
  CloseHandle_(Snapshot)
  CloseLibrary(psapi_dll)
EndProcedure
Procedure HtmlHelp(HelpFile.s, Keyword.s)
  Protected AKLIN.tAKLIN,hWnd.l
  Protected HHCtrl_ocx = OpenLibrary(#PB_Any, "HHCtrl.ocx")
  AKLIN\cbStruct = SizeOf(tAKLIN)
  AKLIN\fReserved = 0
  AKLIN\pszKeywords = Keyword
  AKLIN\fIndexOnFail = #True
  hWnd=CallFunction(HHCtrl_ocx, "HtmlHelpW",0, @HelpFile, #HH_KEYWORD_LOOKUP, AKLIN)
  If hWnd
    ID = 0
    g_ID_Search = 1
    g_class.s = "Button"
    EnumChildWindows_(hWnd, @enumChildren(), 0)
    SendMessage_(hWnd_Find, #BM_CLICK, 0, 0)
    CallFunction(HHCtrl_ocx, "HtmlHelpW", 0, @HelpFile, #HH_DISPLAY_TOPIC, 0)
    CloseLibrary(HHCtrl_ocx)
    While GetTopWindow_(hWnd):Delay(100):Wend
  EndIf
EndProcedure
FullPrograName$=Space(#MAX_PATH)
GetModuleFileName_(#NUL,@FullPrograName$,#MAX_PATH)
_KillOtherProcess(FullPrograName$,GetCurrentProcessId_())
HelpFile$ = ProgramParameter()
SearchWord$ = ProgramParameter()
HtmlHelp(HelpFile$, SearchWord$)