FastDefrag - оптимизации системного диска.

# Перепроверяем более точно все диски, определённые ранее как HDD, с помощью утилиты Smartctl.exe
        # Диски могут не определиться как SSD, так как с помощью PS это сделать гарантированно не возможно.
        $TableDrives.Values.Where({
            if ( $_.MediaType -like '*HDD*' )
            {
                # Для всех возможных типов подключения.
                foreach ( $Type in 'sat,auto','sat','auto','ata','scsi','nvme' )
                {
                    # Если диск определился как SSD.
                    if (( & $Smartctl -d $Type -i $_.DriveLetter ) -like '*Solid State Device*' )
                    {
                        # Переименовываем его МедиаТип HDD в МедиаТип SSD, и прерываем дальнейшее определение этого диска.
                        if ( $_.MediaType -eq 'VirtualHDD' ) { $_.MediaType = 'VirtualSSD' }
                        else                                 { $_.MediaType = 'SSD'        }
                        break
                    }
                }
            }
        })

:: Сценарий получения информации по жестким дискам в системе, и определения SSD дисков
:DiskInfo
set "DiskLOG=%temp%\Diskpart.log"
set "DiskLOG2=%temp%\Diskpart2.log"
set "WmicLog=%temp%\Wmic.log"
set "HDDLog=%temp%\TempHDD.log"
set "SSDLog=%temp%\TempSSD.log"
del "%WmicLog%" 2>nul & del "%HDDLog%" 2>nul & del "%SSDLog%" 2>nul & del "%DiskLOG2%" 2>nul
echo. list volume | diskpart | findstr /i " Partition Simple " | findstr /i " GB MB " >%DiskLOG%
chcp 866 >nul
for /f "tokens=1*" %%I in (' type "%DiskLOG%" ') do (
set "LogLine=%%I %%J"
set "LogLine=!LogLine:* NTFS =!" & set "LogLine=!LogLine:* FAT32 =!" & set "LogLine=!LogLine:* Simple =!" & set "LogLine=!LogLine:* Partition =!"
for /f "tokens=1,2" %%K in ('echo.!LogLine!^| findstr /i " MB GB "') do (
  set "SizeMB=1"
  if "%%L"=="MB" ( set "SizeMB=%%K" & set "SizeMB=!SizeMB:~3!" )
  set "ExcludeLine=~~~~~~~"
  if "!SizeMB!"=="" set "ExcludeLine=%%K %%L"
  for /f "tokens=3*" %%O in (' echo.%%I %%J ^| find /i /v " !ExcludeLine! " ^| find /i /v " Hidden " ') do (
   echo.%%O %%P>>"%DiskLOG2%"
  )
)
)
for /f "tokens=1,2*" %%I in (' type "%DiskLOG2%" ') do (
set "DiskLetter=%%I"
set "GBDisk=%%J %%K"
set "GBDisk=!GBDisk:* Simple =!" & set "GBDisk=!GBDisk:* Partition =!"
set "DiskType=" & set "DiskType2="
2>nul wmic logicaldisk !DiskLetter!: get FileSystem,Name,VolumeName | find /i "!DiskLetter!:">>%WmicLog%
type %WmicLog% | find /i "!DiskLetter!:" >nul && ( set "DiskType={0e}HDD{#}"& set "DiskType2=HDD" )
for %%A in (sat2,sat,auto,ata,scsi,nvme) do (
  set "D=%%A"
  if "%%A"=="sat2" set "D=sat,auto"
  %Smartctl% -d !D! -i !DiskLetter!: |>nul find /i "Solid State Device" && (set "DiskType={0a}SSD{#}"& set "DiskType2=SSD")
)
if "!DiskType2!"=="SSD" (<nul set /p Drives=!DiskLetter!: >>%SSDLog%)
if "!DiskType2!"=="HDD" (<nul set /p Drives=!DiskLetter!: >>%HDDLog%)
for /f "tokens=1,3*" %%I in (' type "%WmicLog%" ^| find /i "!DiskLetter!:" ') do (
  set "DiskName=%%J %%K"
  set "DiskFS=%%I"
  for /f "tokens=1,2" %%L in ('echo.!GBDisk!') do (
   set "Tab=    "
   if %%L GTR 9 set "Tab=   " & if %%L GTR 99 set "Tab=  " & if %%L GTR 999 set "Tab= "
   set "DiskSize=%%L %%M!Tab!"
   if "!DiskFS!"=="NTFS" set "DiskFS=NTFS "
   %ch%                  !DiskType! {08}Disk ^> {0f}!DiskLetter!: {08}^|{#} !DiskSize! {08}^|{#} !DiskFS! {08}^|{#} !DiskName! {\n #}
  )
)
)
chcp 65001 >nul
for /f "tokens=*" %%I in (' 2^>nul type %SSDLog% ') do set "SSDdisk=%%I"
for /f "tokens=*" %%I in (' 2^>nul type %HDDLog% ') do set "HDDdisk=%%I"
if "%SSDdisk%"=="" ( set "TrimDisks=У вас нет {0a}SSD{#} дисков"
) else ( set "TrimDisks={0d}Выполнить{#} TRIM для {0a}SSD{#} дисков: {0a}%SSDdisk%{#}" )
if "%HDDdisk%"=="" ( set "DfrgDisks=У вас нет {0e}HDD{#} дисков"
) else ( set "DfrgDisks={0d}Выполнить{#} дефрагментацию {0e}HDD{#} дисков: {0e}%HDDdisk%{#}" )
del "%DiskLOG%" 2>nul & del "%DiskLOG2%" 2>nul & del "%WmicLog%" 2>nul & del "%HDDLog%" 2>nul & del "%SSDLog%" 2>nul
exit /b