Батники - вопросы и решения

@set @x=1/*
@echo off
title Автоматическое обновление Windows
set self=%0
ver| >nul find "10.0"|| (
call :msg "  Только для Windows 10!  " " Ошибка" 16
exit
)
>nul 2>&1 dism.exe|| (
call :msg "  Требуются права Администратора!  " " Ошибка" 16
exit
)
if defined PROCESSOR_ARCHITEW6432 (
start %windir%\Sysnative\cmd.exe /c %0
exit
)
cls
echo/
set TrustedInstaller=*S-1-5-80-956008885-3418522649-1831038044-1853292631-2271478464
set var=%windir%\System32\UsoClient.exe
icacls.exe %var%| >nul find "BUILTIN"|| goto next
call :status РАЗРЕШЕНО 0a
call :msg "  Запретить автоматическое обновления Windows?  " " Вопрос" 289
if %errorlevel%==1 (
cls
echo/
echo Запрещаю автоматическое обновление...
echo --------------------------------------------------------------
takeown.exe /f %var% /a
icacls.exe %var% /reset
icacls.exe %var% /inheritance:r /grant %TrustedInstaller%:(F^) *S-1-15-2-1:(RX^)
echo --------------------------------------------------------------
echo Готово.
call :status ЗАПРЕЩЕНО 0c
call :msg "  Автоматическое обновление Windows запрещено!  " " Информация" 64
)
exit
:next
set donor=%windir%\System32\ntdll.dll
for %%i in (%var%) do set fname=%%~nxi
call :status ЗАПРЕЩЕНО 0c
call :msg "  Разрешить автоматическое обновление Windows?  " " Вопрос" 289
if %errorlevel%==1 (
cls
echo/
echo Разрешаю автоматическое обновление...
echo --------------------------------------------------------------
echo f| >nul xcopy /oxy %donor% %tmp%\%fname%
pushd %tmp%
>nul icacls.exe %fname% /save %fname%.acl
popd
icacls.exe %var% /reset
icacls.exe %var% /setowner %TrustedInstaller%
icacls.exe %windir%\System32 /restore %tmp%\%fname%.acl
del /q %tmp%\%fname%*
echo --------------------------------------------------------------
echo Готово.
call :status РАЗРЕШЕНО 0a
call :msg "  Автоматическое обновление Windows разрешено!  " " Информация" 64
)
exit
:status
color %2
echo/
echo --------------------------------------------------------------
echo        Статус автоматического обновления: * %1 *
echo --------------------------------------------------------------
echo/
exit /b
:msg
for /f "delims=" %%y in ('cscript.exe //nologo //e:jscript %self% %1 %2 %3') do exit /b %%y
*/
WScript.Echo (WScript.CreateObject("WScript.Shell").Popup(WScript.Arguments(0), 0, WScript.Arguments(1), WScript.Arguments(2)))