PECMD (перевод хелпа)

Но примерный скрипт для создания двух разделов есть

PART -usb list disk,DrvAll
FORX* %DrvAll%,XEnvi,
{* TEAM DISK TEnvi,%XEnvi%,1|FIND $%TEnvi%=,PART -devid list disk %XEnvi%,TEnvi!EXIT -
TEAM LPOS DEnvi=USBSTOR,1,%TEnvi%|IFEX $%DEnvi%=0,EXIT -!TEAM FDRV *idlec DEnvi=*:|MSTR DEnvi=<1>%DEnvi%|DISK %DEnvi%,%XEnvi%,1,|EXIT -
}
Envi DiskN=7 `Номер диска (hd7)
ENVI DiskFS=FAT32 `Файловая система первого раздела
ENVI DiskLN=First.1 `Метка первого раздела
ENVI F2PtnD=%CurDir%\Utilites\Flash2Ptn.exe `Самораспаковка для установки на второй скрытый раздел
TEAM ENVI UTFold=%Temp%\2k10\UTmake|PATH %UTFold%
ENVI ScPart=10 `Размер второго раздела в мегабайтах
ENVI Spart.Check=1 `Если 1, создавать второй раздел, если 0 - единственый раздел
PART -phy list part %DiskN%#1,TEnvi
TEAM MSTR TEnvi=<8>%TEnvi%
MSTR SelDsk=1,2,%TEnvi%
CALL @RePart
EXIT
_SUB RePart,W360H195,Repartition & format %SelDsk%\,,,,,
LABE ,L20T12W160H22,SelDsk=%SelDsk%,,0x0000AA,14
ITEM UDFRPrt,L240T12W100H25,Repartition,TEAM CALL UForm|Envi @RepMess=DONE!|WAIT 2000|Envi @RepMess=|EXIT
LABE RepMess,L20T70W320H22,Start,,0x0000AA,14
TEAM PART -devid list disk %DiskN%,TEnvi|MSTR TEnvi=<~12>%TEnvi%|SED TEnvi=1,USBSTOR\\DISK\&VEN_,,%TEnvi%|SED TEnvi=1,\&REV.*,,%TEnvi%|SED TEnvi=1,\&,_,%TEnvi%|LABE ,L10T32W220H22,%TEnvi%,,,12
_END
_SUB UForm
TEAM DISK TEnvi,%DiskN%,1|CALC EFIldr=0|FIND $%TEnvi%=,!ENVI SelDSK=%TEnvi%
IFEX $%Spart.Check%=1,FIND $%ScPart%=EFI-loaders,TEAM CALC EFIldr=1|EXEC --hide --wait %F2PtnD% -nr -InstallPath="%UTFold%\2Ptn"|SIZE TEnvi=%UTFold%\2Ptn|CALC #ScPart=%TEnvi%/920000+2|FILE %UTFold%\2Ptn
TEAM PART list disk %DiskN%,TEnvi|MSTR ,DiskFF=<1*>%TEnvi%
TEAM CALC Size2P=%ScPart%M*%Spart.Check%|CALC #Start2P=(%DiskFF%-%Size2P%)/1M*1M
FORX* 2 1,NEnvi,TEAM PART -phy list part %DiskN%#%NEnvi%,TEnvi|MSTR TEnvi=<8>%TEnvi%|MSTR DEnvi=3,2,%TEnvi%|MSTR TEnvi=1,2,%TEnvi%|FIND $%TEnvi%<>,TEAM SHOW ,%TEnvi%|FIND $%DEnvi%<>,SHOW ,%DEnvi%
ENVI @RepMess=Clear first 1MB (zero padding)
PUTF \\.\PhysicalDrive%DiskN%,0,*1M 0x00 0x00
IFEX $%Size2P%>0,
{* ENVI @RepMess=Create MBR and second partition
PART -mbr -up -super init %DiskN%
SHOW - %DiskN%#1
PART -mbr -up -hup -force -super -usb -fs %DiskN%#1 0x0E %Start2P% %Size2P%
TEAM WAIT 200|PART -phy list part %DiskN%#1,TEnvi|MSTR TEnvi=<8>%TEnvi%|MSTR DEnvi=3,2,%TEnvi%|MSTR TEnvi=1,2,%TEnvi%|FIND $%DEnvi%<>,SHOW ,%DEnvi%
FIND $%TEnvi%<>,ENVI SelDsk=%TEnvi%!FIND $%SelDsk%=,TEAM FDRV *idlec TEnvi=*:|MSTR SelDsk=<1>%TEnvi%|SHOW %DiskN%#1,%SelDsk%!SHOW %DiskN%#1,%SelDsk%
TEAM ENVI @RepMess=Format the second partition|IFEX $%Size2P%>2048M,EXEC --hide --wait --exe:#20 tmp %SelDsk%!DFMT %SelDsk%,FAT,,1
TEAM WAIT 200|FDRV *setvol %SelDsk%=Part_II|PART -hextp -phy list drv %SelDsk%,TEnvi|MSTR FS2P=<2>%TEnvi%
FIND $%EFIldr%=1,TEAM ENVI @RepMess=Copy files from archive to second partition|EXEC --hide =%F2PtnD% -nr -InstallPath="%SelDsk%"|ENVI EFIldr=
}
TEAM ENVI @RepMess=Create the first partition|CALC #Size1P=%Start2P%-1048576|SHOW - %DiskN%#1
PART -mbr -up -hup -force -super -usb -fs %DiskN%#1 0x0E 1048576 %Size1P%
TEAM WAIT 200|PART -phy list part %DiskN%#1,TEnvi|MSTR TEnvi=<8>%TEnvi%|MSTR DEnvi=3,2,%TEnvi%|MSTR TEnvi=1,2,%TEnvi%
FIND $%TEnvi%=,SHOW %DiskN%#1,%SelDsk%!FIND $%DEnvi%<>,SHOW ,%DEnvi%
TEAM ENVI @RepMess=Format the first partition
TEAM SITE ?XEnvi=FVER,%WinDir%\System32\cmd.exe|LSTR XEnvi=1,%XEnvi%
FIND $%OsVer%=5,ENVI NEnvi=EXEC --hide --wait --exe:#21 tmp %SelDsk% /Q /Y /X /FS:%DiskFS%!ENVI NEnvi=DFMT %SelDsk%,%DiskFS%,,1
FIND $%DiskFS%=FAT32,ENVI NEnvi=EXEC --hide --wait --exe:#20 tmp %SelDsk%
IFEX $%Size1P%<2048M,ENVI NEnvi=DFMT %SelDsk%,FAT,,1
TEAM %NEnvi%|IFEX $%errorlevel%<>0,EXEC --hide --wait --exe:#20 tmp %SelDsk%
TEAM PART -hextp -phy list drv %SelDsk%,TEnvi|MSTR FS1P=<2>%TEnvi%|FIND $%DiskLN%=,!CALL NewLabel
TEAM ENVI @RepMess=Mount partition(s)|SHOW - %DiskN%#1|CALC TEnvi=lnot(%EFIldr%)*%ScPart%
IFEX $%TEnvi%=0,TEAM CALC TEnvi=1|CALC XEnvi=2|ENVI NEnvi=a|ENVI DEnvi=-a!TEAM CALC TEnvi=2|CALC XEnvi=1|ENVI NEnvi=-a|ENVI DEnvi=a
PART -mbr -force -super -usb %DiskN%#%TEnvi% %NEnvi% %FS1P% 1048576 %Size1P%
IFEX $%Size2P%>0,PART -mbr -force -super -usb %DiskN%#%XEnvi% %DEnvi% %FS2P% %Start2P% %Size2P%
TEAM PART update %DiskN%|WAIT 200|PART -phy list part %DiskN%#1,TEnvi|MSTR TEnvi=<8>%TEnvi%|MSTR DEnvi=3,2,%TEnvi%|MSTR TEnvi=1,2,%TEnvi%
FIND $%TEnvi%=,SHOW %DiskN%#1,%SelDsk%!FIND $%DEnvi%<>,SHOW ,%DEnvi%
IFEX $%Size2P%>0,
{* TEAM PART -phy list part %DiskN%#2,TEnvi|MSTR TEnvi=<8>%TEnvi%|MSTR DEnvi=3,2,%TEnvi%|MSTR TEnvi=1,2,%TEnvi%
FIND $%TEnvi%=,TEAM FDRV *idlec TEnvi=*:|MSTR TEnvi=<1>%TEnvi%|SHOW %DiskN%#2,%TEnvi%
}
_END
MESS Done!
EXIT
_SUB NewLabel
TEAM ENVI DiskL=%DiskLN%|ENVI DiskLN=|FIND $%DiskL%=,ENVI TEnvi=0!ENVI TEnvi=1
LOOP #%TEnvi%>0,
{* TEAM FDRV *setvol %SelDsk%=%DiskL%|FDRV *vol TEnvi=%SelDsk%
FIND $%TEnvi%=%DiskL%,TEAM ENVI TEnvi=0|EXIT
TEAM STRL TEnvi=,%DiskL%|CALC TEnvi=%TEnvi%-2|LSTR DiskL=%TEnvi%,%DiskL%
IFEX $%TEnvi%<1,TEAM FDRV *setvol %SelDsk%=UTmake|ENVI TEnvi=0|EXIT
}
_END
`В скрипте используются утилиты format2003.exe и fat32format, вшитые в ехе-шник как ресурсы #21 и #20. Они задействуются вместо стандартных средств форматирования при выборе файловой системы NTFS или ExFAT под ОС/РЕ ХР (поскольку там штатный форматировщик этого может не позволить), и для форматирования в FAT32 с поддержкой больших разделов.

Тогда скрипт будет таким (под 10-й двухраздельной флешке будут показаны 2 буковки, а под остальными ОС - второй раздел `Invisible`)

TEAM ENVI^ EnviMode=1|SET$ &NL=0d 0a|FDRV &Drvs=*:
FORX * %&Drvs%,&D,TEAM PART list drv %&D%,&&V|MSTR &&hd=<9>%&V%|^SET &Drv[%&hd%]=%%&Drv[%&hd%]%%%&D%
TEAM PART list disk,&&AllDsk|ENVI &&FindLIST=|SET &D1=
FORX * %&AllDsk%,&Find,
{* TEAM PART -devid list disk %&Find%,&DskID|MSTR &&hd,&&SZ,&&Bus=<1><2><9>%&DskID%
TEAM SED &DskID=1,DISK\&VEN_,1 ,%&DskID%|SED &DskID=1,IDE\\DISK,1 ,%&DskID%|SED &DskID=1,\&PROD_,_,%&DskID%
TEAM MSTR &DskID=<-1>%&DskID%|SED &DskID=1,\&REV, ,%&DskID%|SED &DskID=1,\\, ,%&DskID%|SED &DskID=1,___, ,%&DskID%
TEAM MSTR &DskID=<1>%&DskID%|SED &DskID=8,_, ,%&DskID%
FIND $%&DskID%=,SET &DskID=-
IFEX #%Bus%=2, SET Bus=(ATAPI)
IFEX #%Bus%=3, SET Bus=(ATA)
IFEX #%Bus%=7,TEAM SET Bus=(USB_HDD)|^SET &TEnvi=%%&Drv[%hd%]%%|FORM TEnvi=%&TEnvi%|FIND $%TEnvi%=DRIVE_USBFLASH,TEAM SET Bus=(USB_Flash)
IFEX #%Bus%=11, SET Bus=(SATA)
IFEX #%&SZ%>2G, @TEAM CALC &SZ=%&SZ%/1G#1| SET SZ=%&SZ%G! IFEX #%&SZ%>2M, @TEAM CALC &SZ=%&SZ%/1M#1| SET SZ=%&SZ%M
^SET &FindLIST=%&FindLIST%%&NL%%&Find%,%&Bus%,%&SZ%,%&DskID%,%%&Drv[%hd%]%%
FIND $%Bus%=(USB_Flash),
{* TEAM PART -hextp -phy -phy# list part %&Find%#2,TEnvi|MSTR &SZ2,TEnvi=<5><9>%TEnvi%
FIND $%TEnvi%=,EXIT -!FIND $%&SZ2%=0,EXIT -
IFEX #%&SZ2%>2G, @TEAM CALC &SZ2=%&SZ2%/1G#1| SET SZ2=%&SZ2%G! IFEX #%&SZ2%>2M, @TEAM CALC &SZ2=%&SZ2%/1M#1| SET SZ2=%&SZ2%M
^SET &FindLIST=%&FindLIST%%&NL%%&Find%#2,%&Bus%,%SZ2%,%&DskID%,Invisible
}}
FILE .\HDD_data.txt
WRIT .\HDD_data.txt,$*,%&FindLIST%

Результат

0,(ATA),465.8G,ST500DM002-1BC142,C:D:E:F:
1,(USB_Flash),87.4M,GENERIC FLASH DISK,G:
1#2,(USB_Flash),82M,GENERIC FLASH DISK,Invisible
2,(USB_Flash),7.5G,JETFLASH TRANSCEND 8GB,H:
2#2,(USB_Flash),12M,JETFLASH TRANSCEND 8GB,Invisible

скрипт

TEAM ENVI HdData=|SET$ &NL=0d 0a|PART list disk,AllDrv
FORX* %AllDrv%,CurDrv,
{* TEAM PART -devid list disk %CurDrv%,DskNam|MSTR HdNum,HdSize,HdBus=<1><2><9>%DskNam%|SED DskNam=1,DISK\&VEN_, ,%DskNam%
TEAM MSTR DskNam=<~13>%DskNam%|SED DskNam=1,\&REV, ,%DskNam%|SED DskNam=1,\\, ,%DskNam%
TEAM MSTR DskNam=<1>%DskNam%|SED DskNam=1,\&PROD_, ,%DskNam%|SED DskNam=6,_, ,%DskNam%
FIND $%DskNam%=, SET DskNam=-
'IFEX #%HdSize%>2G, @TEAM CALC HdSize=%HdSize%/1G#1|ENVI HdSize=%HdSize%G!IFEX #%HdSize%>2M,@TEAM CALC 'HdSize=%HdSize%/1M#1|ENVI HdSize=%HdSize%M
IFEX #%HdBus%=2,ENVI HdBus=ATAPI!IFEX #%HdBus%=3,ENVI HdBus=ATA!IFEX #%HdBus%=11,ENVI HdBus=SATA
IFEX #%HdBus%=7, TEAM ENVI HdBus=USB_HDD|DISK TEnvi,%CurDrv%,1|FORM TEnvi=%TEnvi%|FIND $%TEnvi%=DRIVE_USBFLASH,ENVI HdBus=USB_Flash
ENVI HdData=%HdData%%&NL%%HdNum% %HdBus% %HdSize% %DskNam%
ENVI PtsData=
PART list part %CurDrv%,AllPrt
FORX* %AllPrt%,CurPrt,
{* IFEX $%CurPrt%<1,EXIT -!
'TEAM PART list part %CurDrv%#%CurPrt%,TEnvi|MSTR PtSize,PtLet=<5><8>%TEnvi%|FIND $%PtLet%=,ENVI PtLet=*
'ENVI HdData=%HdData%|%CurPrt%,%PtLet%,%PtSize%
TEAM PART list part %CurDrv%#%CurPrt%,TEnvi|MSTR PtSize,PtLet=<5><8>%TEnvi%|FIND $%PtLet%=,ENVI PtLet=*:
ENVI PtsData=%PtsData%%PtLet%,%PtSize%|
}
ENVI HDdata=%HDdata% %PtsData%
}
'MESS %HDdata%
FILE .\HDD_data.txt
WRIT .\HDD_data.txt,$*,%HDdata%
EXIT

результат

0 SATA 240057409536 KINGSTON SUV400S *:,103809024|C:,38461767680|G:,201490169856|
1 SATA 1000204886016 TOSHIBA HDWD110 *:,103809024|*:,44970278912|D:,955126906880|
2 USB_Flash 32937869312 [JF700] TRANSCEND I:,28641853440|