Использование NTBOOT и WINBOOT в WEE.MBR

This fetches the three files, which will all – when wimboot executes – be made available at multiple locations in a virtual filesystem. The locations are as follows:
\
\Boot
\Boot\Fonts
\Boot\Resources
\Sources
\EFI
\EFI\Boot
\EFI\Microsoft
\EFI\Microsoft\Boot
So for any given file, say test.bcd, it will be made available with the filename BCD at all the locations given above:
\BCD
\Boot\BCD
\Boot\Fonts\BCD
\Boot\Resources\BCD
\Sources\BCD
\EFI\BCD
\EFI\Boot\BCD
\EFI\Microsoft\BCD
\EFI\Microsoft\Boot\BCD

Скрипт

@echo off
set "BCDSTORE=BCD"
pushd %~dp0
chcp 437 >nul
bcdedit /createstore %BCDSTORE%
set "mybcdedit=bcdedit /store %BCDSTORE%"
%mybcdedit% /create {ramdiskoptions} /d "Ramdisk Options"
%mybcdedit% /set {ramdiskoptions} ramdisksdidevice Boot
%mybcdedit% /set {ramdiskoptions} ramdisksdipath \Boot\boot.sdi
for /f "Tokens=3" %%x in ('%mybcdedit% /create /d "Windows Boot WIM" /application osloader') do set GUID=%%x
%mybcdedit% /set %GUID% systemroot \Windows
%mybcdedit% /set %GUID% detecthal Yes
%mybcdedit% /set %GUID% winpe Yes
%mybcdedit% /set %GUID% osdevice ramdisk=[boot]\Boot\boot.wim,{ramdiskoptions}
%mybcdedit% /set %GUID% device ramdisk=[boot]\Boot\boot.wim,{ramdiskoptions}
%mybcdedit% /set %GUID% loadoptions DDISABLE_INTEGRITY_CHECKS
%mybcdedit% /set %GUID% nointegritychecks On
%mybcdedit% /set %GUID% testsigning On
%mybcdedit% /set %GUID% bootmenupolicy legacy
%mybcdedit% /set %GUID% nx AlwaysOff
%mybcdedit% /ems %GUID% Off
%mybcdedit% /set %GUID% locale en-US
%mybcdedit% /create {bootmgr} /d "Windows Boot Manager"
%mybcdedit% /set {bootmgr} timeout 30
%mybcdedit% /set {bootmgr} displayorder %GUID%
%mybcdedit% /set {bootmgr} loadoptions DDISABLE_INTEGRITY_CHECKS
%mybcdedit% /set {bootmgr} nointegritychecks ON
%mybcdedit% /set {bootmgr} testsigning ON
%mybcdedit% /set {bootmgr} locale en-US
echo+
echo Press any key to view BCD...
pause >nul
bcdedit /enum all /store %BCDSTORE%
echo+
echo Press any key to exit...
pause >nul