Полезные CMD файлы

cd /d "%~dp0"
set /a _t=0
set /a _c=0
if exist "*.WA" for /f "delims=" %%# in ('dir /b /os *.WA') do call set /a _t+=1
if %_t% equ 0 exit /b
for /f "delims=" %%# in ('dir /b /os *.WA') do (set "addon=%%#"&set "dest=%%~n#"&call :prepare)
echo.
echo Done.
echo Press any key to exit.
pause >nul
exit /b
:prepare
if exist "%dest%" (
if exist "%dest%\Registry\NSudoC.exe" (exit /b) else (rd /s /q "%dest%")
)
set /a _c+=1
echo %_c%/%_t%: %addon%
echo.
bin\7zr x "%addon%" -o"%dest%" * -r >nul
if not exist "%dest%\Tasks.txt" rd /s /q "%dest%"&exit /b
md "%dest%\Registry\"
copy /y bin\NSudoC.exe "%dest%\Registry\" >nul
copy /y bin\Integrator.cmd "%dest%\" >nul
copy /y bin\Reg2Wim.cmd "%dest%\" >nul
pushd "%dest%\"
findstr /i ".dll" Tasks.txt >nul && for /f "tokens=1,2 delims=:" %%a in ('findstr /i ".dll" Tasks.txt') do (
if not exist "Files\%%b" md "Files\%%b"
move /y "%%a" "Files\%%b\" >nul
)
for /f "tokens=1,2 delims=:" %%a in ('findstr /i ":" Tasks.txt ^|findstr /i /v ".dll"') do (
if not exist "Files\%%b" md "Files\%%b"
move /y "%%a" "Files\%%b\" >nul
)
for /f "delims=" %%# in ('dir /b *.reg') do call Reg2Wim.cmd %%#
move /y *.reg Registry\ >nul
del /f /q Reg2Wim.cmd Tasks.txt
popd
exit /b