zPnP - Автоматическая установка драйверов

@echo off
title Indexes Drivers
cls
set "arch=x64"
if /i %PROCESSOR_ARCHITECTURE%==x86 if not defined PROCESSOR_ARCHITEW6432 set "arch=x86"
cd /d "%~dp0"
If %arch%==x64 (set os=_x64) else (set os=)
set idx=Tools\idx2%os%.exe
set Infsp=Tools\InfSplit.exe
set "conx=Tools\conx.exe"
for /f "delims=" %%a in (Tools\fold.cfg) do >nul 2>nul dir /s /b /a:-d "%%a\*.inf"&&call :ind %%a
cls
echo.
%ConX% color 0a
echo        --- Completed  !!!  ---
%ConX% color 0f
echo.
%ConX% color 07
set /p xx=^>^>
Exit
:ind
:: Максимальное к-во процессов
set maxprocess=4
call :_startprocess w10x86 %1
call :_startprocess w10x64 %1
call :_startprocess w8.1x64 %1
call :_startprocess w8.1x86 %1
call :_startprocess w8x64 %1
call :_startprocess w8x86 %1
call :_startprocess w7x64 %1
call :_startprocess w7x86 %1
set maxprocess=1
call :_startprocess
goto :eof
:_startprocess
set count=0
for /f "skip=3" %%a in ('tasklist /fi "imagename eq  idx2%os%.exe"') do set /a count +=1
if %count% lss %maxprocess% goto _1
::Тут можно поставить задержку, чтобы не грузить компьютер
goto _startprocess
:_1
if .%1==. goto :eof
cls
echo.
%conx% color 0e
Echo.Indexes *** [%1]    Dir ^< %2 ^>
Echo.
start "idx2" %idx% /config:%1 /wait:0 %2
goto :eof