Способ создания "заливок" и их применение.

Смотри

:: Полный путь к файлу (с кавычками) создаваемого образа.
set image="D:\Win10.wim"
:: Полный путь к подключаемому VHD (с кавычками)
set fname="C:\VirtualBox\Windows.vhd"
:: Имя создаваемого образа
set name="Windows 10 x86 2004"
:: Описание создаваемого образа
set desc="Windows 10 x86 2004 Build Date 22.08.2020"
:: ------------------------- Основное тело скрипта ---------------------------------
cd /d %~dp0
>nul dism||(Powershell -Command "& { Start-Process \"%~0\" -verb RunAs}"& exit)
(
echo select vdisk file=%fname%
echo attach vdisk
)| diskpart
set part=1& for %%i in (
b c d e f g h i j k l m n o p q r s t u v w x y z
) do >nul 2>&1 cd %%i:|| (set Drv=%%i& goto assign)
:error
echo Error!
pause
goto quit
:assign
(
echo select vdisk file=%fname%
echo select part %part%
echo assign letter=%Drv%
)| diskpart
>nul 2>&1 cd %Drv%:|| goto :error
if exist %Drv%:\Windows goto next
(
echo select volume %Drv%
echo remove
)| diskpart
set /a part+=1
goto assign
:next
wimlib-imagex.exe append %Drv%:\ %image% %name% %desc% --create --norpfix --compress=fast --config=Exclusion_List.ini
:quit
(
echo select vdisk file=%fname%
echo detach vdisk
)| diskpart