Slimm Windows

: 1, 2 Next

Displaying options
Hide Avatars Rank images Post images Smilies Signatures Show Show opened Downloadable pictures

Отправлено: 01-Apr-2021 13:49

xnik

Longevity: 5 years 1 month
Posts: 390
REPUTATION:6
[+] [-]
Location: СССР

Подскажите какие файлы Windows можно удалить, что бы она была поменьше. Не нарушая стабильности, так сказать средней урезанности.
Вот например обнаружил у себя D3DCompiler_33.dll потом идет с номером 34 35 и до D3DCompiler_47.dll, и таких групп несколько.
На сайте microsoft указанно следующие: обновление не заменяет ранее выпущенное обновление.
Но главный интерес это конечно же winsxs, как бы ее сократить?

Отправлено: 01-Apr-2021 14:16 (after 26 minutes)

rezorustavi

Longevity: 7 years 11 months
Posts: 928
REPUTATION:55
[+] [-]
Location: Грузия, город Рустави

84511winsxs

Очистку, в том числе и от старых обновлений делать лучше всего штатными средствами, через свойства диска.
Другими средствами, как твикеры winsxs тогать не рекомендую, так как рано или поздно в чём-то появятся проблемы и не поймете где роется собака...

Last edited by rezorustavi on 2021-04-01 14:28; edited 3 times in total

Отправлено: 01-Apr-2021 14:19 (after 3 minutes)

korsak7

Longevity: 8 years 11 months
Posts: 1082
REPUTATION:62
[+] [-]

Изобретение лисапеда - устойчивая тенденция на юсбторе в последнее время

это конечно же winsxs, как бы ее сократить

Dism /Online /Cleanup-Image /StartComponentCleanup

Отправлено: 02-Apr-2021 14:49 (after 1 day)

xnik

Longevity: 5 years 1 month
Posts: 390
REPUTATION:6
[+] [-]
Location: СССР

Вот еще вариант, здесь присутствует ключ /ResetBase (удалить замененные версии)

Dism.exe /Online /Cleanup-Image /StartComponentCleanup /ResetBase

Отправлено: 03-Apr-2021 17:15 (after 1 day 2 hours)

sergeysvirid

Longevity: 8 years 11 months
Posts: 2466
REPUTATION:127
[+] [-]
Location: 65 регион (GMT+11)

84532Вот еще вариант

xnik,

А вот ещё вариант:

:: Выполнить максимальную очистку (CLEANMGR) диска (C:\) без диалога с пользователем (/VeryLowDisk)
CLEANMGR /VeryLowDisk /D C:\

-P.S.
Вобщем запуск батника вот такого плана, думаю будет более, чем достаточно:

@echo off
reg query "HKU\S-1-5-19\Environment" >nul 2>&1
if %errorlevel% GTR 0 (
cls
powershell.exe -windowstyle hidden -noprofile "Start-Process '%~dpnx0' -Verb RunAs"
exit
)
for /f "tokens=6 delims=[]. " %%G in ('ver') do if %%G LEQ 7601 goto :WIN7
for /f "tokens=6 delims=[]. " %%G in ('ver') do if %%G GEQ 9600 goto :WIN81_10
:WIN7
:: Очистка хранилища компонентов из папки WinSxS в Windows 7
start "" /b /w Dism.exe /Online /Cleanup-Image /StartComponentCleanup
goto :END
:WIN81_10
:: Очистка хранилища компонентов из папки WinSxS в Windows 10 и 8.1
start "" /b /w Dism.exe /Online /Cleanup-Image /StartComponentCleanup /ResetBase
:END
:: Выполнить максимальную очистку (CLEANMGR) диска (C:\) без диалога с пользователем (/VeryLowDisk)
start "" /b /w cleanmgr.exe /VeryLowDisk /D C:\

Отправлено: 03-Apr-2021 17:45 (after 29 minutes)

Ander_73

Longevity: 6 years 10 months
Posts: 3458
REPUTATION:127
[+] [-]

sergeysvirid, не смог удержаться

set opt=& for /f "tokens=6 delims=[]. " %%G in ('ver') do if %%G GTR 7601 set opt=/ResetBase
start "" /b /w Dism.exe /Online /Cleanup-Image /StartComponentCleanup %opt%

Отправлено: 03-Apr-2021 17:56 (after 11 minutes)

dimo70

Longevity: 6 years
Posts: 3990
REPUTATION:26
[+] [-]
Location: BG

sergeysvirid, скрипт очень понравился и сделал репак.
Ander_73, а етот код куда нужно поставить и зачем?

_________________
Signed off for violation of forum rules

Отправлено: 03-Apr-2021 21:43 (after 3 hours)

UserX

Longevity: 8 years 7 months
Posts: 776
REPUTATION:30
[+] [-]

84555а етот код куда нужно поставить и зачем?

dimo70, у sergeysvirid в коде имеются два варианта вызова dism
Для Win7:
Dism.exe /Online /Cleanup-Image /StartComponentCleanup
Для Win81_10:
Dism.exe /Online /Cleanup-Image /StartComponentCleanup /ResetBase
Видно, что эти два вызова отличаются лишь наличием в команде для Win81_10 дополнительного ключа /ResetBase
Вот Ander_73 это дело красиво и реализовал, введя переменную opt, которая, в зависимости от версии Windows, будет либо пустой, либо равной /ResetBase
В результате, скрипт стал без безусловных переходов goto и укоротился:

@echo off
reg query "HKU\S-1-5-19\Environment" >nul 2>&1
if %errorlevel% GTR 0 (
cls
powershell.exe -windowstyle hidden -noprofile "Start-Process '%~dpnx0' -Verb RunAs"
exit
)
set opt=& for /f "tokens=6 delims=[]. " %%G in ('ver') do if %%G GTR 7601 set opt=/ResetBase
start "" /b /w Dism.exe /Online /Cleanup-Image /StartComponentCleanup %opt%
:: Выполнить максимальную очистку (CLEANMGR) диска (C:\) без диалога с пользователем (/VeryLowDisk)
start "" /b /w cleanmgr.exe /VeryLowDisk /D C:\

Правда, в обоих случаях остаётся вопрос с версией Windows 8, или для неё подходит вариант для 8.1_10

Отправлено: 03-Apr-2021 21:58 (after 14 minutes)

dimo70

Longevity: 6 years
Posts: 3990
REPUTATION:26
[+] [-]
Location: BG

UserX, спасибо за разяснение по скрипту.

Windows 8 думаю никто не пользует, так как актуальная версия 8.1.
Подключу в мою полезность FastClean.
А как насчет команду "Dism.exe /online /Cleanup-Image /SPSuperseded"? Имеет смысль подключать в скрипт очистки?

_________________
Signed off for violation of forum rules

Отправлено: 03-Apr-2021 22:14 (after 15 minutes)

Ander_73

Longevity: 6 years 10 months
Posts: 3458
REPUTATION:127
[+] [-]

UserX,

@echo off
>nul 2>&1 reg query "HKU\S-1-5-19\Environment"|| (
powershell.exe -windowstyle hidden -noprofile "Start-Process '%~dpnx0' -Verb RunAs"
exit
)
set opt=& for /f "tokens=6 delims=[]. " %%G in ('ver') do if %%G GTR 7601 set opt=/ResetBase
Dism.exe /Online /Cleanup-Image /StartComponentCleanup %opt%
cleanmgr.exe /VeryLowDisk /D C:\

---
Зачем очищать старое окно, если открываем новое? (cls)
Зачем нужен start, если запускаем процесс в этом же окне и с ожиданием (/b/w)?
Ну, это так, придирки

Отправлено: 03-Apr-2021 22:37 (after 22 minutes)

Undeground

Longevity: 5 years 1 month
Posts: 31
REPUTATION:-6
[+] [-]

А что означает эта ошибка .
При этом очистка проходит. Win7x32.

Отправлено: 04-Apr-2021 02:36 (after 3 hours)

sergeysvirid

Longevity: 8 years 11 months
Posts: 2466
REPUTATION:127
[+] [-]
Location: 65 регион (GMT+11)

84554не смог удержаться

Ander_73, Привет!

И не нужно себя удерживать, ты же знаешь, что "скриптописец" из меня некудышный, а вот ты уже знаещь толк в этом деле, так что не удерживай себя никогда, подправляй, когда видишь что можно (и нужно) подправить.-

84564А что означает эта ошибка

Undeground,
Приветствую!

Видимо в системе отсутствует обновление KB2852386 (по идее входит в состав KB3125574)
https://www.outsidethebox.ms/15444/

Отправлено: 04-Apr-2021 14:46 (after 12 hours)

Undeground

Longevity: 5 years 1 month
Posts: 31
REPUTATION:-6
[+] [-]

(по идее входит в состав KB3125574)

Пишет что установлено.

Отправлено: 04-Apr-2021 18:49 (after 4 hours)

sov44

Longevity: 7 years
Posts: 32
REPUTATION:4
[+] [-]
Location: г. Киров

84564что означает эта ошибка

В семёрке нет ключа StartComponentCleanup для dism.
Чистить систему нужно с помощью Cleanmgr, типа

Set rst=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches
REG Add "%rst%\Recycle Bin" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Add "%rst%\Temporary Files" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG add "%rst%\Update Cleanup" /v StateFlags0001 /t REG_DWORD /d 2 /f 1>nul 2>nul
REG Delete "%rst%\Compress old files" /f 2>nul
Cleanmgr /sagerun:1

Отправлено: 04-Apr-2021 21:36 (after 2 hours 46 minutes)

Undeground

Longevity: 5 years 1 month
Posts: 31
REPUTATION:-6
[+] [-]

В семёрке нет ключа StartComponentCleanup для dism.
Чистить систему нужно с помощью Cleanmgr, типа

Спасибо,работает без этой ошибки.

Page 1 of 2

: 1, 2 Next

Current time is: 05-Dec 12:31

All times are UTC + 3

You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum